这东西感觉比JMail好用，用Godday的空间没JMail组件才发现这东西。
<%
function CDO_Mail(m_body)
'----------------------
'邮件配置开始
'----------------------
mail_smtp="smtp.qq.com" 'smtp 服务器，根据邮箱设置
mail_user="332003288@qq.com" '邮箱账号
mail_pass="请自己更改密码" '邮箱密码
mail_to="332003288@qq.com" '接收邮箱
mail_title="来自www.eims.org.cn的邮件" '邮件标题
mail_body=m_body '邮件内容，根据信息类型获取，若要更改请在提交页面更改。
'----------------------
'邮件配置结束，一下代码请不要随意改动
'----------------------
Const cdoSendUsingMethod="http://schemas.microsoft.com/cdo/configuration/sendusing"
Const cdoSendUsingPort=2
Const cdoSMTPServer="http://schemas.microsoft.com/cdo/configuration/smtpserver"
Const cdoSMTPServerPort="http://schemas.microsoft.com/cdo/configuration/smtpserverport"
Const cdoSMTPConnectionTimeout="http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
Const cdoSMTPAuthenticate="http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
Const cdoBasic=1
Const cdoSendUserName="http://schemas.microsoft.com/cdo/configuration/sendusername"
Const cdoSendPassword="http://schemas.microsoft.com/cdo/configuration/sendpassword"
Dim objConfig
Dim objMessage
Dim Fields
Set objConfig = Server.CreateObject("CDO.Configuration")
Set Fields = objConfig.Fields
With Fields
.Item(cdoSendUsingMethod) = cdoSendUsingPort
.Item(cdoSMTPServer) = mail_smtp
.Item(cdoSMTPServerPort) = 25
.Item(cdoSMTPConnectionTimeout) = 10
.Item(cdoSMTPAuthenticate) = cdoBasic
.Item(cdoSendUserName) = mail_user
.Item(cdoSendPassword) = mail_pass
.Update
End With
Set objMessage = Server.CreateObject("CDO.Message")
Set objMessage.Configuration = objConfig
With objMessage
.BodyPart.Charset = "utf-8"
.To=mail_to
.From=mail_user
.Subject=mail_title
.HtmlBody=mail_body
.Send
End With
Set Fields = Nothing
Set objMessage = Nothing
Set objConfig = Nothing
end function
%>
