如图所示电路，要求完成实现按钮按压次数的计数及显示，按一次按钮，计数值加1（要求按十进制累加）。
http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/album/item/2f609f80899bcfe2bd3e1ec9.html
计数及显示范围是：0~99，超过99则自动归零。
要求对按钮的检测用中断实现，数码显示用动态扫描（数码管为共阴数码管）。
请设计实现该功能的完整程序。
悬赏分：50 - 解决时间：2010-5-12 17:51
最佳答案：
;----------------------------------------------------------------------
;用PROTEUS仿真，显示器使用7SEG-MPX2-CC
;===================================
ORG 0000H
AJMP START
ORG 0013H
AJMP X1_INT
START:
MOV SP, #60H
MOV IE, #84H
MOV R3, #0
;-------------------
MAIN:
LCALL DISPLAY
SJMP MAIN
;-----------------------------------
X1_INT:
MOV A, R3
ADD A, #1
DA A
MOV R3, A ;R3 = 00~99H
X1_LOOP:
LCALL DISPLAY
JNB P3.3, X1_LOOP
RETI
;-----------------------------------
DISPLAY:
MOV A, R3
ANL A, #0FH ;取出个位.
MOV DPTR, #TAB
MOVC A, @A + DPTR
MOV P2, #0FFH ;关闭显示.
MOV P0, A ;输出段码.
CLR P2.1 ;P2.1=0
LCALL DELAY
;-------------------
MOV A, R3
SWAP A
ANL A, #0FH ;取出十位.
MOVC A, @A + DPTR
MOV P2, #0FFH ;关闭显示.
MOV P0, A ;输出段码.
CLR P2.0 ;P2.0=0
LCALL DELAY
RET
;-----------------------------------
DELAY:
MOV R4, #250
DJNZ R4, $
RET
;-----------------------------------
TAB:
DB 3FH, 06H, 5BH, 4FH, 66H
DB 6DH, 7DH, 07H, 7FH, 6FH
end
;===================================
回答者： 做而论道 - 十三级 2010-5-8 00:23
提问者对于答案的评价：good
原题网址：http://z.baidu.com/question/151649564.html
;----------------------------------------------------------------------
