如下图所示,承受垂直荷载的二力杆桁架,杆件长度为L0=1000mm,初始夹角为20°,各杆件截面面积均为A=50mm²,设材料的弹性模量为E=210GPa,对此结构进行特征值屈曲分析和几何非线性分析。
FINISH !退出当前处理器
/CLEAR !清除当前数据库文件,开始新的启动
/PLOPTS,DATE,0 !设置不显示日期和时间
/PREP7 !进入前处理器
L0=1000
THETA=20
*AFUN,DEG !设置角度单位为度
A=50
EM=2.1E5
L1=2*L0*COS(THETA)
H1=L0*SIN(THETA) !定义参数
ET,1,LINK1 !定义单元类型1为LINK1
MP,EX,1,EM !定义材料1的弹性模量
R,1,A !定义单元的实常数1(此处为LINK1单元的横截面面积为A)
K,1
K,2,0.5*L1,H1
K,3,L1 !创建关键点
L,1,2
L,2,3 !连接关键点生成线
LESIZE,ALL,,,1 !给所选择的线设置网格单元的大小
LMESH,ALL !对所有选择的线进行单元网格划分
DK,1,ALL
DK,3,ALL !在关键点上施加自由度约束
SAVE !将当前的数据信息保存到一个文件里
FINISH !退出当前处理器
!特征值屈曲分析
!=====================================================================
/SOLU !进入求解处理器
ANTYPE,0 !定义分析类型为静态分析
FK,2,FY,-2E5 !对关键点施加集中力荷载
PSTRES,ON !打开预应力效应
SOLVE !计算求解
FINISH !退出当前处理器
/SOLU !进入求解处理器
ANTYPE,1 !定义分析类型为稳定性分析(已完成带有预应力效应计算的静态分析)
BUCOPT,LANB,1 !定义特征值提取方法和特征值提取个数
MXPAND,1 !对于模态和屈曲分析,指定将要扩展的模态数
SOLVE !计算求解
FINISH !退出当前处理器
/POST1 !进入通用后处理器
SET,LIST !列表荷载步的结果
PLDISP,2 !显示结构的变形形状(变形前的形状为模型边界)
FINISH !退出当前处理器
!几何非线性分析
!=====================================================================
RESUME !将文件中的数据恢复到数据库中
/SOLU !进入求解处理器
ANTYPE,0 !定义分析类型为静态分析
NLGEOM,1 !在静态或完全瞬态分析中打开大变形效应
NSUBST,100 !指定子步数
OUTRES,ALL,ALL !控制写入到数据库中的结果数据
ARCLEN,ON !打开弧长法
FK,2,FY,-2E5 !对关键点施加集中力荷载
SOLVE !计算求解
/POST26 !进入时间历程后处理器
NSOL,2,2,U,Y !从结果文件中取出节点数据(2节点的Y方向位移),并赋给定义的变量2
PROD,3,2,,,,,,-1 !变量相乘运算
PROD,4,1,,,,,,2E5 !变量相乘运算
XVAR,3 !指定显示的X变量
PLVAR,4 !图形显示变量(荷载位移曲线)
联系客服