自动生成EXCEL文件完整示例

* 编号：A0004
* 功能：自动生成EXCEL文件完整示例
CLOSE DATABASES all
CREATE CURSOR yafox (dm C(4),mc C(10),bz C(40))
INSERT INTO yafox (dm,mc,bz) valueS ("xwy","许文远","[e-mail]")
INSERT INTO yafox (dm,mc,bz) valueS ("fox","雅狐论坛","www.yafox.com")
FOR i=1 TO 100
 INSERT INTO yafox (dm,mc,bz) valueS (TRANSFORM(i,"@l 9999"),SUBSTR(SYS(2015),2),"")
NEXT

WAIT "正在访问 Excel 软件……" WINDOW NOWAIT
ExcelSheet = GetObject('','Excel.Sheet')
If Type("ExcelSheet")#'O'
 WAIT CLEAR
 MessageBox( "访问Excel失败！请检查你的系统是否正确安装 Excel 软件！",48,"Excel不正常")
 RETURN .f.
ENDIF

WAIT "正在设置Excel，请稍侯…" WINDOW NOWAIT
ExcelApp = ExcelSheet.APPLICATION
*设置工作区
ExcelApp.VISIBLE = .f.
ExcelApp.ActiveWindow.WindowState = 2
ExcelActiveSheet = ExcelApp.ActiveSheet
ExcelActiveSheet.Name = "yafox"

*设置页面信息
ExcelActiveSheet.PageSetup.PaperSize =9
ExcelActiveSheet.PageSetup.TopMargin    =32 *2.84
ExcelActiveSheet.PageSetup.BottomMargin =18 *2.84
ExcelActiveSheet.PageSetup.LeftMargin   =19 *2.84
ExcelActiveSheet.PageSetup.RightMargin  =19 *2.84
ExcelActiveSheet.PageSetup.HeaderMargin =22 *2.84
ExcelActiveSheet.PageSetup.FooterMargin =13 *2.84
ExcelActiveSheet.PageSetup.Orientation =1
ExcelActiveSheet.PageSetup.PrintTitleRows = "$2:$2"
ExcelActiveSheet.PageSetup.PrintTitleColumns="$A:$A"
ExcelActiveSheet.PageSetup.RightHeader  = "&9 许文远 (C)"
ExcelActiveSheet.PageSetup.CenterFooter  = "&9 第 &"+"P 页 / 共 &"+"N 页"
ExcelActiveSheet.PageSetup.RightFooter  = "&9 www.yafox.com"
ExcelActiveSheet.PageSetup.CenterHorizontally  = .t.
ExcelActiveSheet.PageSetup.CenterVertically    = .f.

*创建Excel打印格式
If FCOUNT("yafox")>26
 ExcelEndColunm=Chr(Int((FCOUNT("yafox")-1)/26)+64)+;
  Chr(FCOUNT("yafox")%26+64)
Else
 ExcelEndColunm=Chr(FCOUNT("yafox")+64)
ENDIF
ExcelActiveSheet.Rows("1:2").HorizontalAlignment= 3
ExcelActiveSheet.Rows("1:2").VerticalAlignment  = 2
ExcelActiveSheet.Rows("1").ShrinkToFit = .t.
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Font.Name = "宋体"
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Font.Size = 11
ExcelActiveSheet.Rows("1").Font.Size = 13
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Font.Bold = .f.
ExcelActiveSheet.Rows("1:2").Font.Bold = .t.
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Font.Italic = .f.
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Font.Underline = .f.
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).WrapText=.t.
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Orientation =0
ExcelActiveSheet.Columns("A"+ExcelEndColunm).NumberFormatLocal = ""
ExcelActiveSheet.Columns("A").RowHeight = 14
ExcelActiveSheet.Rows("1").RowHeight = 16
ExcelActiveSheet.Columns("A").ColumnWidth = 5
ExcelActiveSheet.Columns("B").ColumnWidth = 10
ExcelActiveSheet.Columns("C").ColumnWidth = 40
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+ALLTRIM(STR(2+RECCOUNT()))).Borders(1).Weight = 2
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+ALLTRIM(STR(2+RECCOUNT()))).Borders(2).Weight = 2
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+ALLTRIM(STR(2+RECCOUNT()))).Borders(3).Weight = 2
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+ALLTRIM(STR(2+RECCOUNT()))).Borders(4).Weight = 2
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+"2").Borders(1).Weight = 3
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+"2").Borders(2).Weight = 3
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+"2").Borders(3).Weight = 3
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+"2").Borders(4).Weight = 3
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+"1").MergeCells = .t.

WAIT "正在输出数据……" WINDOW NOWAIT
*输出数值
ExcelActiveSheet.Cells( 1, 1).value = "Excel表格生成演示"
ExcelActiveSheet.Cells( 2, 1).value = "代码"
ExcelActiveSheet.Cells( 2, 2).value = "名称"
ExcelActiveSheet.Cells( 2, 3).value = "备注"
SCAN
 FOR i=1 TO FCOUNT()
  ExcelActiveSheet.Cells( 2+RECNO() , i).value = EVALUATE(FIELD(i))
 NEXT
ENDSCAN
WAIT CLEAR
ExcelApp.VISIBLE = .t.
MESSAGEBOX("生成Excel完毕")

ExcelApp.ActiveWorkbook.SaveAs("C:\yafox")
ExcelApp.ActiveWorkbook.close
ExcelApp.quit               && 关闭Excel
release ExcelSheet