编程思路破译
C22赋值:1日前的收盘价
ZT赋值:如果(收盘价-C22)*100/C22>=(10-0.01*100/C22),返回1,否则返回0
LG赋值:当前值是近成交量(手)周期的最大值
FZG赋值:最高价/60日前的最低价< 1.6 AND 最高价/20日前的最低价< 1.5 AND 最高价/4日前的最低价< 1.3 AND 最高价/10日前的最低价< 1.5 AND 统计5日中满足ZT的天数<=3 AND 统计50日中满足ZT的天数<=5
ZLC赋值:开盘价/1日前的收盘价>1.07 AND 收阴线AND LG>60 AND FZG
BGY赋值:1日前的ZT AND 开盘价/1日前的收盘价>1.01 AND 收阴线AND LG>60 AND FZG
BGYY赋值:1日前的ZT AND 最高价/1日前的收盘价>1.07 AND 收阳线AND LG>100 AND FZG
EBY赋值:开盘价/1日前的收盘价>1.01 AND 收阴线AND 成交量(手)< 1日前的成交量(手) AND 1日前的ZT AND FZG
HF赋值:收盘价=最高价 AND 收盘价/1日前的收盘价>1.095 AND 平盘AND 最低价< 收盘价
TZBS31赋值: 1日前的HF AND 成交量(手) <= 0.7*1日前的成交量(手)
BGS31赋值: 1日前的成交量(手)=100日内成交量(手)的最高值 AND 1日前的收盘价 > 2日前的收盘价 AND 成交量(手) <= 0.7*1日前的成交量(手)
BBZTS31赋值: 2日前的ZT AND 2日前的成交量(手) >= 2* 3日前的成交量(手) AND 1日前的ZT AND 1日前的成交量(手) >= 2* 2日前的成交量(手) AND 1日前的成交量(手)=60日内成交量(手)的最高值 AND 成交量(手) <= 0.7*1日前的成交量(手)
BLZT赋值: 1日前的ZT AND 1日前的成交量(手) >= 2日前的成交量(手)*2 AND 1日前的成交量(手)=30日内成交量(手)的最高值 AND 成交量(手)<= 0.5*1日前的成交量(手)
ZTBGS31赋值: 2日前的ZT AND 1日前的成交量(手)=100日内成交量(手)的最高值 AND 成交量(手) <= 0.7*1日前的成交量(手)
当满足条件ZTBGS31ORBBZTS31ORBGS31ORTZBS31ORHFORZLCORBGYORBGYYOREBYORBLZT时,在最高价*1.015位置画9号图标,画红色
输出均价:成交额(元)/成交量(手)/100,NODRAW,画黄色
BK赋值:如果属于某板块,返回0.2,否则返回如果属于某板块,返回0.2,否则返回如果属于某板块,返回0.05,否则返回0.1
当满足条件(收盘价>=计算涨停价ANDC=最高价)时,在收盘价和开盘价位置之间画柱状线,宽度为2.7,0不为0则画空心柱.,COLORFF00FF
当满足条件(收盘价<=计算跌停价ANDC=最低价)时,在收盘价和开盘价位置之间画柱状线,宽度为2.7,0不为0则画空心柱.,COLOR00BF00
TC赋值:取反 AND 取反
LB10赋值:最高价>=1日前的收盘价*1.085 AND 收盘价< 1日前的收盘价*1.11 AND 收盘价< 最高价 AND TC
当满足条件LB10时,在最高价和开盘价和收盘价的较大值位置之间画柱状线,宽度为0.02,0不为0则画空心柱.,COLORFF00FF
QB10赋值:收盘价*1.085< 1日前的收盘价 AND 收盘价*1.13>1日前的收盘价 AND 收盘价>最低价 AND TC
当满足条件QB10时,在最低价和开盘价和收盘价的较小值位置之间画柱状线,宽度为0.02,0不为0则画空心柱.,COLORFF8000
LB20赋值:最高价>1日前的收盘价*1.196 AND 收盘价< 1日前的收盘价*1.22 AND 收盘价< 最高价
当满足条件LB20时,在最高价和开盘价和收盘价的较大值位置之间画柱状线,宽度为0.02,0不为0则画空心柱.,COLORFF00FF
QB20赋值:收盘价*1.192< 1日前的收盘价AND 收盘价*1.26>1日前的收盘价 AND 收盘价>最低价
当满足条件QB20时,在最低价和开盘价和收盘价的较小值位置之间画柱状线,宽度为0.02,0不为0则画空心柱.,COLORFF8000
向上跳空赋值:收盘价和开盘价的较小值>1日前的收盘价和开盘价的较大值
输出明日涨停参考:收盘价*1.1,NODRAW,画黄色
输出明日创业涨停:收盘价*1.2,NODRAW,画黄色
当满足条件向上跳空=1时,在开盘价和收盘价位置之间画柱状线,宽度为0.4,0不为0则画空心柱.,画黄色
HS赋值:成交量(手)/当前流通股本(手)*100
输出换手比:HS/1日前的HS,NODRAW,COLORFF00FF
输出三一:开盘价和收盘价的较大值-开盘价-收盘价的绝对值/3,NODRAW,画黄色
输出二一:(开盘价+收盘价)/2,NODRAW,画黄色
输出三二:开盘价和收盘价的较小值+开盘价-收盘价的绝对值/3,NODRAW,画黄色
输出虚31:最高价和最低价的较大值-(最高价-最低价)/3,NODRAW,画黄色
输出虚21:(最低价+最高价)/2,NODRAW,画黄色
输出虚32:最高价和最低价的较小值+(最高价-最低价)/3,NODRAW,画黄色
AA11赋值:(1日后的(未作平滑处理)收盘价+2日后的(未作平滑处理)收盘价+3日后的(未作平滑处理)收盘价)/3>开盘价和收盘价的较大值
输出高于实顶:如果AA11,返回1,否则返回0,画黄色,NODRAW
T11赋值:10日内最低价距今天数的最后一日取值设为常数
T11H赋值:T11日前的最高价的最后一日取值设为常数
CC赋值:到最后交易的周期的最后一日取值设为常数
T12赋值:上次到最后交易的周期>CC+T11ANDH>T11H距今天数的最后一日取值设为常数
T12H赋值:T12日前的最高价的最后一日取值设为常数
T13赋值:上次到最后交易的周期>CC+T12ANDH>T12H距今天数的最后一日取值设为常数
T13H赋值:T13日前的最高价的最后一日取值设为常数
所属板块赋值:字符串相加
当满足条件开盘价>0时,在横轴0纵轴0.00位置书写文字,画黄色
当满足条件开盘价>0时,在横轴0纵轴0.05位置书写文字
当满足条件开盘价>0时,在横轴0.08纵轴0.05位置书写文字,COLORFF00FF
自由流通市值赋值:字符串相加
当满足条件开盘价>0时,在横轴0纵轴0.09位置书写文字,画黄色
一字板赋值:最低价=最高价 AND (收盘价+0.005-1日前的收盘价)/1日前的收盘价*100>=10
当满足条件一字板时,在1日前的收盘价和收盘价位置之间画柱状线,宽度为2.8,-1不为0则画空心柱.,COLORFFEEBB
收阴赋值:收阴线AND (开盘价-收盘价)/开盘价>0.04
收阳赋值:收阳线AND (收盘价-开盘价)/开盘价>0.04
实体大于4%赋值:如果收阴线,返回收阴,否则返回收阳
当满足条件实体大于4%时,在二一和二一位置之间画柱状线,宽度为2,0不为0则画空心柱.,画深灰色
TK赋值:收阳线AND 开盘价>=1日前的收盘价和开盘价的较大值+0.01 OR 开盘价>=1日前的收盘价+0.01
当满足条件TK时,在开盘价和(收盘价-开盘价)*0.01+开盘价位置之间画柱状线,宽度为3,0不为0则画空心柱.,画黄色
GLT赋值:高量天数日内成交量(手)距今天数的最后一日取值设为常数
高量顶赋值:如果到最后交易的周期<=GLT+1,返回GLT日前的收盘价和开盘价的较大值的最后一日取值设为常数,否则返回无效数
高量底赋值:如果到最后交易的周期<=GLT+1,返回如果(GLT日前的收盘价和开盘价的较大值-GLT日前的收盘价和开盘价的较小值)/GLT日前的开盘价<=0.033,返回GLT日前的最低价,否则返回GLT日前的收盘价和开盘价的较小值的最后一日取值设为常数,否则返回无效数
当满足条件高量底时,在高量底和高量底位置之间画柱状线,宽度为5,0不为0则画空心柱.,画绿色
当满足条件高量顶时,在高量顶和高量顶位置之间画柱状线,宽度为5,0不为0则画空心柱.,画红色
当满足条件是否最后一个周期时,在高量顶位置书写文字,画红色
当满足条件是否最后一个周期时,在高量底位置书写文字,画绿色
程序源码
C22:=REF(C,1);
ZT:=IF((C-C22)*100/C22>=(10-0.01*100/C22),1,0);
LG:=TOPRANGE(VOL);
FZG:=H/REF(L,60)< 1.6 AND H/REF(L,20)< 1.5 AND H/REF(L,4)< 1.3 AND H/REF(L,10)< 1.5 AND COUNT(ZT,5)<=3 AND COUNT(ZT,50)<=5;
ZLC:=O/REF(C,1)>1.07 AND C< O AND LG>60 AND FZG;
BGY:=REF(ZT,1) AND O/REF(C,1)>1.01 AND C< O AND LG>60 AND FZG;
BGYY:=REF(ZT,1) AND H/REF(C,1)>1.07 AND C>O AND LG>100 AND FZG;
EBY:=O/REF(C,1)>1.01 AND C< O AND V< REF(V,1) AND REF(ZT,1) AND FZG;
HF:=C=H AND C/REF(C,1)>1.095 AND C=O AND L< C;
TZBS31:= REF(HF,1) AND V <= 0.7*REF(V,1);
BGS31:= REF(V=HHV(V,100),1) AND REF(C,1) > REF(C,2) AND V <= 0.7*REF(V,1);
BBZTS31:= REF(ZT,2) AND REF(V,2) >= 2* REF(V,3) AND REF(ZT,1) AND REF(V,1) >= 2* REF(V,2) AND REF(V=HHV(V,60),1) AND V <= 0.7*REF(V,1);
BLZT:= REF(ZT,1) AND REF(V,1) >= REF(V,2)*2 AND REF(V=HHV(V,30),1) AND V<= 0.5*REF(V,1);
ZTBGS31:= REF(ZT,2) AND REF(V=HHV(V,100),1) AND V <= 0.7*REF(V,1);
DRAWICON(ZTBGS31 OR BBZTS31 OR BGS31 OR TZBS31 OR HF OR ZLC OR BGY OR BGYY OR EBY OR BLZT,H*1.015,9),COLORRED;
均价:AMOUNT/VOL/100,NODRAW,COLORYELLOW;
BK:=IF(INBLOCK('科创板'),0.2,IF(INBLOCK('创业板'),0.2,IF(INBLOCK('ST板块'),0.05,0.1)));
STICKLINE((C>=ZTPRICE(REF(C,1),BK) AND C=H),C,O,2.7,0),COLORFF00FF;
STICKLINE((C<=DTPRICE(REF(C,1),BK) AND C=L),C,O,2.7,0),COLOR00BF00;
TC:=NOT(INBLOCK('创业板')) AND NOT(INBLOCK('科创板'));
LB10:=H>=REF(C,1)*1.085 AND C< REF(C,1)*1.11 AND C< H AND TC;
STICKLINE(LB10,H,MAX(O,C),0.02,0),COLORFF00FF;
QB10:=C*1.085< REF(C,1) AND C*1.13>REF(C,1) AND C>L AND TC;
STICKLINE(QB10,L,MIN(O,C),0.02,0),COLORFF8000;
LB20:=H>REF(C,1)*1.196 AND C< REF(C,1)*1.22 AND C< H;
STICKLINE(LB20,H,MAX(O,C),0.02,0),COLORFF00FF;
QB20:=C*1.192< REF(C,1)AND C*1.26>REF(C,1) AND C>L;
STICKLINE(QB20,L,MIN(O,C),0.02,0),COLORFF8000;
向上跳空:=MIN(C,O)>REF(MAX(C,O),1);
明日涨停参考:C*1.1,NODRAW,COLORYELLOW;
明日创业涨停:C*1.2,NODRAW,COLORYELLOW;
STICKLINE(向上跳空=1,O,C,0.4,0),COLORYELLOW;
HS:=VOL/CAPITAL*100;
换手比:HS/REF(HS,1),NODRAW,COLORFF00FF;
三一:MAX(O,C)-ABS(O-C)/3,NODRAW,COLORYELLOW;
二一:(O+C)/2,NODRAW,COLORYELLOW;
三二:MIN(O,C)+ABS(O-C)/3,NODRAW,COLORYELLOW;
虚31:MAX(H,L)-(H-L)/3,NODRAW,COLORYELLOW;
虚21:(L+H)/2,NODRAW,COLORYELLOW;
虚32:MIN(H,L)+(H-L)/3,NODRAW,COLORYELLOW;
AA11:=(REFXV(C,1)+REFXV(C,2)+REFXV(C,3))/3>MAX(O,C) ;
高于实顶:IF(AA11,1,0),COLORYELLOW,NODRAW;
T11:=CONST(LLVBARS(L,10));
T11H:=CONST(REF(H,T11));
CC:=CONST(CURRBARSCOUNT);
T12:=CONST(BARSLAST(CURRBARSCOUNT>CC+T11 AND H>T11H));
T12H:=CONST(REF(H,T12));
T13:=CONST(BARSLAST(CURRBARSCOUNT>CC+T12 AND H>T12H));
T13H:=CONST(REF(H,T13));
所属板块:=STRCAT('所属板块： ',STRCAT(STRCAT(STRCAT(' 【行业】：',HYBLOCK),STRCAT(' 【地域】：',DYBLOCK)),STRCAT(' 【概念】：',GNBLOCK)));
DRAWTEXT_FIX(O>0,0,0.00,0,所属板块),COLORYELLOW;
DRAWTEXT_FIX(O>0,0,0.05,0,'同花顺概念:');
DRAWTEXT_FIX(O>0,0.08,0.05,0,EXTERNSTR(0,1)),COLORFF00FF;
自由流通市值:=STRCAT(STRCAT('自由流通市值：', CON2STR(C*FINANCE(46)/100000000,2)),'亿');
DRAWTEXT_FIX(O>0,0,0.09,0,自由流通市值),COLORYELLOW;
一字板:=L=H AND (C+0.005-REF(C,1))/REF(C,1)*100>=10;
STICKLINE(一字板,REF(C,1),C,2.8,-1),COLORFFEEBB;
收阴:=O>C AND (O-C)/O>0.04;
收阳:=O< C AND (C-O)/O>0.04;
实体大于4%:=IF(O>C,收阴,收阳);
STICKLINE(实体大于4%,二一,二一,2,0),COLORGRAY;
TK:=C>O AND O>=REF(MAX(C,O),1)+0.01 OR O>=REF(C,1)+0.01 ;
STICKLINE(TK, O,(C-O)*0.01+O,3,0),COLORYELLOW;
GLT:=CONST(HHVBARS(V,高量天数));
高量顶:=IF(CURRBARSCOUNT<=GLT+1,CONST(REF(MAX(C,O),GLT)),DRAWNULL);
高量底:=IF(CURRBARSCOUNT<=GLT+1,CONST(IF((REF(MAX(C,O),GLT)-REF(MIN(C,O),GLT))/REF(O,GLT)<=0.033,REF(L,GLT),REF(MIN(C,O),GLT))),DRAWNULL);
STICKLINE(高量底,高量底,高量底,5,0),COLORGREEN;
STICKLINE(高量顶,高量顶,高量顶,5,0),COLORRED;
DRAWTEXT(ISLASTBAR,高量顶,STRCAT(' ','安全线')),COLORRED;
DRAWTEXT(ISLASTBAR,高量底,STRCAT(' ','保命线')),COLORGREEN;
注：
馆内各种公式为学习编程而保存，实战使用前一定要看其中是否有未来函数并自己亲自测试成功率，决不能依据公式名称的描述和形容去投资，据此入市造成投资损失由投资者自己承担。
发文不易，如获益，欢迎赞赏，赞赏必复！
联系客服
