公式技巧(0001~0100)
0001--主图显示代码及板块
一、显示板块
例一：
DRAWTEXT(BARPOS=SYSPARAM(2),H,'\N所属板块:'+BLKNAME),ALIGN4,COLORYELLOW;
例二：
DRAWTEXT(SYSPARAM(2)=BARPOS,C,'所属板块:'+BLKNAME),ALIGN4,COLORYELLOW;
例三：
DRAWTEXT(SYSPARAM(2)=BARSCOUNT(C),H,'[所属版块]:'+BLKNAME),ALIGN4,COLORYELLOW;
二、显示代码及板块
S:=STKLABEL;
DRAWTEXT(SYSPARAM(2)=BARPOS,C,S),ALIGN4,COLORYELLOW;
DRAWTEXT(BARPOS=SYSPARAM(2),H,'\N 所属板块:'+BLKNAME),ALIGN4,COLORYELLOW;{N与所属板块之间空六格，以显示代码}
-------------------------------------------------------------------------------
0002--主图显示成交量
前四例可实际使用，后三例的思路不错，但量柱过高，部分遮住K线，有待完善。
例一：
BB:=HHV(VOL,SYSPARAM(3)-SYSPARAM(2));
HH:=SYSPARAM(4);
LL:=SYSPARAM(5);
TT:=IF(HH-LL<=2.5,0.25,IF(HH-LL<=5,0.8,IF(HH-LL<=10,2,IF(HH-LL<=20,3,IF(HH-LL<=31,4,IF(HH-LL<=41,5,IF(HH-LL<=50,6,IF(HH-LL<=60,7,IF(HH-LL<=70,8,IF(HH-LL<=80,9,1))))))))));
MA(V/BB*0.9*TT+LL,5)-0.04;
MA(V/BB*0.9*TT+LL,10)-0.04;
MA(V/BB*0.9*TT+LL,34)-0.04;
STICKLINE(C>=REF(C,1),V/BB*0.9*TT+LL-0.04,LL-0.04,4,1)COLOR9090EE;
STICKLINE(C< REF(C,1 ),V/BB*0.9*TT+LL-0.04,LL-0.04,4,1)COLORBLUE;
STICKLINE(C>=O,C,O,8,0),COLOR0055AA;
STICKLINE(C<=O,C,O,8,0),COLOR006600;
STICKLINE(C>=O,C,O,5,0),COLOR0077CC;
STICKLINE(C>=O,C,O,3,0),COLOR0099DD;
STICKLINE(C>=O,H,L,0,0),COLOR00BBFF;
STICKLINE(C<=O,C,O,5,0),COLOR009900;
STICKLINE(C<=O,C,O,3,0),COLOR00BB00;
STICKLINE(C<=O,H,L,0,0),COLOR00EE00
例二：
BB:=HHV(VOL,SYSPARAM(3)-SYSPARAM(2));
HH:=SYSPARAM(4);
LL:=SYSPARAM(5);
TT:=IF(HH-LL<4,0.5,1);
STICKLINE(C>=REF(C,1),VOL/BB*0.8*TT+LL,LL,4,1)COLOR9090EE;
STICKLINE(C< REF(C,1 ),VOL/BB*0.8*TT+LL,LL,4,1)COLORBLUE;
STICKLINE(C>=O,C,O,8,0),COLOR0055AA;
STICKLINE(C<=O,C,O,8,0),COLOR006600;
STICKLINE(C>=O,C,O,5,0),COLOR0077CC;
STICKLINE(C>=O,C,L,3,0),COLOR0099DD;
STICKLINE(C>=O,H,L,0,0),COLOR00BBFF;
STICKLINE(C<=O,C,O,5,0),COLOR009900;
STICKLINE(C<=O,C,O,3,0),COLOR00BB00;
STICKLINE(C<=O,H,L,0,0),COLOR00EE00
例三：
A1:=VOL;
A2:=VOL/CAPITAL*100/15;
A3:=SYSPARAM(5);
A4:=A3-0.3;
STICKLINE(C>0 AND C>REF(C,1),A4,A4+A2,7,1),COLORRED;
STICKLINE(C>0 AND C<=REF(C,1),A4,A4+A2,7,0),COLORCCFF99;
DRAWNUMBER(SYSPARAM(1)=BARPOS AND C>0,A4,A1,1),COLOR00FFFF;
DRAWTEXT(SYSPARAM(1)=BARPOS,A4,'成交量：'),COLOR00FFFF,ALIGN2;
{A2中的15可调；A4中的0.3可调}
例四：
可以调节量柱的高度，不会覆盖K线。使用时，请打开光标。注意，在“管理→系统选项→图形→主图坐标仅随K线变动”处不要打钩。亦显示换手率的数值。
A1:=VOL/CAPITAL*100/15;
A2:=SYSPARAM(5);
A3:=A2-0.3;
STICKLINE(C>=O,A3,A3+A1,7,1),COLORRED;
STICKLINE(C< O,A3,A3+A1,7,0),COLORCCFF99;
换:VOL/CAPITAL*100,LINETHICK0,COLORRED;
例五：
STICKLINE(C>REF(C,1),VOL*0.00001+SYSPARAM(5),SYSPARAM(5),8,1)COLORRED;
STICKLINE(C< REF(C,1),VOL*0.00001+SYSPARAM(5),SYSPARAM(5),8,0)COLORCYAN;
VMA5:MA(VOL*0.00001+SYSPARAM(5),5);
VMA15:MA(VOL*0.00001+SYSPARAM(5),15);
{可通过修改“V*0.00001”中的“0.00001”进行优化}
例六：
STICKLINE(C>REF(C,1)AND C<10,VOL*0.000001+SYSPARAM(5),SYSPARAM(5),8,1)COLORRED;
STICKLINE(C< REF(C,1)AND C<10,VOL*0.000001+SYSPARAM(5),SYSPARAM(5),8,0)COLORCYAN;
{主图一般用百分比坐标，加限定不是好的解决办法}
例七：
MA5:MA(C,P1); { P1:5 P2:10 P3:20 P4:30 N:0.6 M:1}
MA10:MA(C,P2);
MA20:MA(C,P3);
MA30:MA(C,P4);
现价: DYNAINFO(7),COLORWHITE,LINETHICK1 POINTDOT;
STICKLINE(C>O,O,C,7,0),COLORRED;
STICKLINE(C>O,O,C,2,0),COLORB0B0FF;
STICKLINE(C>O,O,C,1,0),COLORYELLOW;
STICKLINE(C>O,L,H,0.1,0),COLORYELLOW;
STICKLINE(C< O,O,C,7,0),COLORFF2020;
STICKLINE(C< O,O,C,4,0),COLORFF6600;
STICKLINE(C< O,O,C,2,0),COLORCYAN;
STICKLINE(C< O,L,H,0.1,0),COLORCYAN;
STICKLINE(C=O AND C>=REF(C,1),O,C,7,0),COLORRED;
STICKLINE(C=O AND C>=REF(C,1),O,C,4,0),COLORB0B0FF;
STICKLINE(C=O AND C>=REF(C,1),O,C,2,0),COLORYELLOW;
STICKLINE(C=O AND C>=REF(C,1),L,H,0.1,0),COLORYELLOW;
STICKLINE(C=O AND C< REF(C,1),O,C,7,0),COLORFF2020;
STICKLINE(C=O AND C< REF(C,1),O,C,4,0),COLORFF6600;
STICKLINE(C=O AND C< REF(C,1),O,C,2,0),COLORCYAN;
STICKLINE(C=O AND C< REF(C,1),L,H,0.1,0),COLORCYAN;
YYTTGG:=BARSCOUNT(HHV(V,0));
BB:=HHV(VOL,SYSPARAM(3)-SYSPARAM(2));//画面中的最大成交量
LL:=SYSPARAM(5);//主图可见K线最低价
STICKLINE(C>=REF(C,1),VOL/BB+LL*M,LL*M,8,1)COLOR50CCEE;
STICKLINE(C< REF(C,1),VOL/BB+LL*M,LL*M,8,0)COLORBLUE;
-------------------------------------------------------------------------------
0003--预测全天成交量、换手率
例一：
根据分时成交量预测
IF(OPENMINUTES(CURRENTTIME)=1,V,(V/OPENMINUTES(CURRENTTIME))*240);
例二：
预测量:STICKLINE(DYNAINFO(7)=CLOSE AND DYNAINFO(10)=AMOUNT,VOL,MAX(VOL,DYNAINFO(17)*REF(MA(VOL,5),1)),7,1),COLORGREEN;
例三：
STICKLINE(DYNAINFO(7)=C AND DYNAINFO(10)=AMOUNT,DYNAINFO(17)*REF(MA(VOL,5),1),0,4,1);
DRAWTEXT(DYNAINFO(7)=C AND DYNAINFO(10)=AMOUNT,V,'←实际V'),COLORRED;
例四：
预换手％:MAX(VOL,DYNAINFO(17)*REF(MA(VOL,5),1))/CAPITAL*100,COLORFFFF00;
-------------------------------------------------------------------------------
0004--收盘线（主图）
IF(DYNAINFO(7)>0,DYNAINFO(7),MA(C,3));
-------------------------------------------------------------------------------
0005--时间周期线示例（主图叠加）
INPUT:N(5,5,100);//参数定义
ZIG(1,N);//高点
FF:=PEAKBARS(1,N,1);
FF:=IF(FF<6,PEAKBARS(1,N,2),FF);
BARST:=SYSPARAM(1);
VARIABLE:ZQ[序列数据量/2]:=1.236;
ZQ[2]:=1.309;
ZQ[3]:=1382;
ZQ[4]:=1.5;
ZQ[5]:=1.618;
ZQ[6]:=1.746;
ZQ[7]:=2;
ZQ[8]:=2.618;
ZQ[9]:=3;
ZQ[10]:=3.236;
ZQ[11]:=4.236;
ZQ[12]:=5.236;//周期线间隔比例，可另行定义
TJ:=FF[BARST]=BARST-BARPOS;
FOR I=1 TO 12 DO TJ:=TJ OR BARPOS-BARST=ROUND((ZQ-1)*FF[BARST]+0.5);
VERTLINE(TJ),POINTDOT,COLORMAGENTA;
必须打开十字光标才可以正常使用。自动寻找高点，可另加参数，改成高低点两用。
公式含义：当K线与高点的时间间隔为十字光标与高点的时间间隔的等于指定比例时，显示竖线。即所谓的时间预测，如果您有好的测试方法，可以仿此代码编制。
这段代码，进行适当的改造，可以向未来延伸，有兴趣的可以自行研究（提示：使用SHIFT函数）。
-------------------------------------------------------------------------------
0006--BACKSET()函数的高级用法
问题：如何在最后一根K线的前第6天，作上标记？
1、先建立一个名为BACKSET-TEST的公式，代码如下：
ISLASTBAR{该周期是否最后一个周期。最后一个周期返回值为1，其余为0}
观察指标线的图形，正如注释所述，最后一天显示为1，这个1我们可理解为信号（条件）成立。其余时间，指标的数值为0，可理解为信号（条件）不成立。
2、巧用BACKSET()函数：
１BACDSET(X,N)注释：向前赋值，若X非0则把当前周期及前N－1周期的数值设置为1;
２示例：把信号向前移。
TJ1:=ISLASTBAR;{最后一天的条件}
TJ2:BACKSET(TJ1,6);
观察TJ2指标线图，发现最后6天的TJ2信号都是1，即一个高度为1的矩形。公式中，还无法判断哪天是倒数第6天。
3、显然倒数第6天，是上面矩形的前沿，如何在公式中，表达这个矩形的前沿？
容易想到的办法：
１倒数第6天的当天，TJ2为1，更早的1天TJ2=0，因此可以编出如下代码：
TJ1:=ISLASTBAR;{最后一天的条件}
TJ2:=BACKSET(TJ1,6);
TJ3:TJ2 AND REF(TJ2,1)=0;
２倒数第6天的当天，TJ2为1，更早的1天TJ2=0，即当天TJ2比早一天的TJ2更大，因此可以编出如下代码：
TJ1:=ISLASTBAR;{最后一天的条件}
TJ2:=BACKSET(TJ1,6);
TJ3:TJ2>REF(TJ2,1);
３倒数第6天的当天，TJ2为1，更早的1天TJ2=0，可以想像为TJ2指标线上穿了一条高度为0.5的水平线，因此可以编出如下代码：
TJ1:=ISLASTBAR;{最后一天的条件}
TJ2:=BACKSET(TJ1,6);
TJ3:CROSS(TJ2,0.5);
４巧用FILTER()过滤函数，FILTER(X,N)，若X非0，可以让X保持当天的值不变，且过滤其后N个周期使之数值为0。
TJ1:=ISLASTBAR;{最后一天的条件}
TJ2:=BACKSET(TJ1,6);
TJ3:FILTER(TJ2,5);{第1次的TJ2保持为1不变，其后的5个周期过滤为0}
这样就初步找到了4种方法，可以标记倒数第6天，若想用图标来标记的话，代码例举如下：
TJ1:=ISLASTBAR;{最后一天的条件}
TJ2:=BACKSET(TJ1,6);
TJ3:=TJ2>REF(TJ2,1);
DRAWICON(TJ3,L,1);
-------------------------------------------------------------------------------
0007--MACD金死叉间最大、最小值
A1:=CROSS("MACD.MACD",0);
A2:=BARSLAST(A1);
A3:=HHVBARS("MACD.MACD" ,A2+1);
A4:=BACKSET(REF(A3>=1,1) AND "MACD.MACD"<0,A3);
A5:=BACKSET(REF(A4=0,1) AND A4=1,2);
高值:IF(FILTER(A5,2),"MACD.MACD",0);
DRAWICON(高值>0,高值,4);
B1:=CROSS(0,"MACD.MACD");
B2:=BARSLAST(B1);
B3:=LLVBARS("MACD.MACD" ,B2+1);
B4:=BACKSET(REF(B3>=1,1) AND "MACD.MACD">0,B3);
B5:=BACKSET(REF(B4=0,1) AND B4=1,2);
低值:IF(FILTER(B5,2),"MACD.MACD",0);
DRAWICON(低值<0,低值,5);
-------------------------------------------------------------------------------
0008--曲线在N天内的平均变化率
{设A,B,R为三条曲线;N,M等为参数。如：A：MA(C,N);B:=MA(C,M);R:=C/REF(C,1)-1;等等}
FA:=(A/REF(A,N)-1)/N;
FB:=(B/REF(B,N)-1)/N;
FR:=(R/REF(R,N)-1)/N;
-------------------------------------------------------------------------------
0009--变动角
{设A,B,R为三条曲线;N,M等为参数。如：A：MA(C,N) ; B:=MA(C,M); R:=C/REF(C,1)-1;等等}
FA:=(A/REF(A,N)-1)/N;
FB:=(B/REF(B,N)-1)/N;
FR:=(R/REF(R,N)-1)/N;
∮A:=ATAN(FA);
∮B:=ATAN(FB);
∮R:=ATAN(FR);
-------------------------------------------------------------------------------
0010--曲线上相距N天的两点的连线的斜率
{设A,B,R为三条曲线;N,M等为参数。如：A：MA(C,N) ; B:=MA(C,M); R:=C/REF(C,1)-1;等等}
KA:=(A-REF(A,N))/N;
KB:=(B-REF(B,N))/N;
KR:=(R-REF(R,N))/N;
-------------------------------------------------------------------------------
0011--倾角
{设A,B,R为三条曲线;N,M等为参数。如：A：MA(C,N) ; B:=MA(C,M); R:=C/REF(C,1)-1;等等}
KA:=(A-REF(A,N))/N;
KB:=(B-REF(B,N))/N;
KR:=(R-REF(R,N))/N;
∠A:=ATAN(KA);
∠B:=ATAN(KB);
∠R:=ATAN(KR);
-------------------------------------------------------------------------------
0012--交叉点
{设A,B,R为三条曲线;N,M等为参数。如：A：MA(C,N) ; B:=MA(C,M); R:=C/REF(C,1)-1;等等}
CAB:=CROSS(A,B);{交叉}
JAB:=LONGCROSS(A,B,N);{维持-交叉}
JYA:=BETWEEN(A,N,M);{介于}
FWA:=RANGE(A,N,M);{范围}
-------------------------------------------------------------------------------
0013--下拐点(由下向上转)
{设A,B,R为三条曲线;N,M等为参数。如：A：MA(C,N) ; B:=MA(C,M); R:=C/REF(C,1)-1;等等}
KA:=(A-REF(A,N))/N;
∠A:=ATAN(KA);
XD1:=LLVBARS(A,N)=M;{以N日最低点}
XD2:=REF(COUNT(A-REF(A,1)<=0,N)=N,M) AND COUNT(A-REF(A,1)>0,M)=M;{以M日变化量的正负}
XD3:=REF(COUNT(∠A-REF(∠A,1)<=0,N)=N,M) AND ∠A>0;{以当日变化角的正负}
-------------------------------------------------------------------------------
0014--上拐点(由上向下转)
{设A,B,R为三条曲线;N,M等为参数。如：A：MA(C,N) ; B:=MA(C,M); R:=C/REF(C,1)-1;等等}
KA:=(A-REF(A,N))/N;
∠A:=ATAN(KA);
SD1:=HHVBARS(A,N)=M;{以N日最低点}
SD2:=REF(COUNT(A-REF(A,1)>=0,N)=N,M) AND COUNT(A-REF(A,1)<0,M)=M;{以当日变化量的正负}
SD3:=REF(COUNT(∠A-REF(∠A,1)>=0,N)=N,M) AND ∠A<0;{以当日变化角的正负}
-------------------------------------------------------------------------------
0015--位置(求得交叉点/拐点到当前的周期)
{设A,B,R为三条曲线;N,M等为参数。如：A：MA(C,N) ; B:=MA(C,M); R:=C/REF(C,1)-1;等等}
CAB:=CROSS(A,B);{交叉}
WZ1:=BARSLAST(CAB);{第一(交叉)点的位置}
WZ2:=REF(WZ1,WZ1+1)+WZ1+2;{第二(交叉)点的位置}
WZ3:=REF(WZ1,WZ2+1)+WZ2+2;{第三(交叉)点的位置}
WZ4:=REF(WZ1,WZ3+1)+WZ3+2;{第四(交叉)点的位置}
WZ5:=REF(WZ1,WZ4+1)+WZ4+2;{第五(交叉)点的位置}
{WZN:=REF(WZ1,WZ(N-1)+1)+WZ(N-1)+2;}
-------------------------------------------------------------------------------
0016--曲线A叠加曲线B
{设A,B,R为三条曲线;N,M等为参数。如：A：MA(C,N) ; B:=MA(C,M); R:=C/REF(C,1)-1;等等}
F:=A/REF(A,1)-1;{A的变化率}
JS:=REF(B,BARSCOUNT(C));{叠加位置(初始)}
DJ:(SUM(F,0)+1)*JS;{叠加曲线(初始位置)}
JD:=REF(B,BARSLAST(条件));{叠加位置(定点)}
DJ:=(SUM(F,0)+1)*JD;{叠加曲线(预定位置)}
-------------------------------------------------------------------------------
0017--任意两条指标线在某数以下（或以上）两次金叉的通式
JM:=CROSS("指标名称.指标线1","指标名称.指标线2");
JMCOUNT:=COUNT(JM,BARSLAST("指标名称.指标线1（或指标线2）"大于或小于某数));
JMTJ:40*("指标名称.指标线1（或指标线2）"小于或大于某数)）;
DRAWTEXT (JMTJ,40,'…………二次金叉');
条件选股:60*(JMTJ AND …………),COLORGREEN;
例一：
MACD在0轴线以下二次金叉
JM:=CROSS("MACD.DIFF","MACD.DEA");
JMCOUNT:=COUNT(JM,BARSLAST("MACD.DEA">=0));
JMTJ:40*("MACD.DEA"<0 AND COUNT(JMCOUNT=2,21)=1);
DRAWTEXT (JMTJ,40,'MACD在0轴线以下二次金叉');
条件选股:60*(JMTJ AND SLOPE(MA(C,5),2)>0),COLORGREEN;
DRAWTEXT (条件选股,50,'5日3%成功率：44.71%');
例二：
KD在60轴线以下二次金叉
JM:=CROSS("KD.K","KD.D");
JMCOUNT:=COUNT(JM,BARSLAST("KD.D">=60));
JMTJ:40*("KD.D"<60 AND COUNT(JMCOUNT=2,21)=1);
DRAWTEXT (JMTJ,"KD.D",'KD在60轴线以下二次金叉');
条件选股:60*(JMTJ AND SLOPE(MA(C,20),3)>0),COLORGREEN;
DRAWTEXT (条件选股,50,'5日3%成功率：50.3%');
例三：
SLOWKD在30轴线以下二次金叉
JM:=CROSS("SLOWKD.K","SLOWKD.D");
JMCOUNT:=COUNT(JM,BARSLAST("SLOWKD.D">=30));
JMTJ:28*("SLOWKD.D"<30 AND COUNT(JMCOUNT=2,21)=1);
DRAWTEXT (JMTJ,28,'SLOWKD在30轴线以下二次金叉');
条件选股:50*(JMTJ AND SLOPE(MA(C,20),2)>0),COLORGREEN;
-------------------------------------------------------------------------------
0018--今收盘对于N日内最低收盘价的涨幅（%）
(C-LLV(C,N))/LLV(C,N)*100;
-------------------------------------------------------------------------------
0019--今收盘对于N日内最高收盘价的跌幅（%）
(HHV(C,N)-C)/HHV(C,N)*100;
-------------------------------------------------------------------------------
0020--股价在过去N日内运行空间的相对位置
(C-LLV(L,N))/(HHV(H,N)-LLV(L,N))*100;
-------------------------------------------------------------------------------
0021--股价上方N1%至N2%处的筹码（%）
AA:=WINNER(C+C*N2/100)*100;
BB:=WINNER(C+C*N1/100)*100;
AA-BB
-------------------------------------------------------------------------------
0022--股价下方N1%至N2%处的筹码（%）
(WINNER(C-C*N1/100)-WINNER(C-C*N2/100))*100;
-------------------------------------------------------------------------------
0023--收盘价N%处的套牢盘
100-(WINNER(C*N/100))*100;
-------------------------------------------------------------------------------
0024--收盘价N%处的获利盘
WINNER(C*N/100)*100;
-------------------------------------------------------------------------------
0025--下影线
(MIN(C,O)-L)/(H-L);
-------------------------------------------------------------------------------
0026--上影线
(H-MAX(C,O))/(H-L)
-------------------------------------------------------------------------------
0027--本周期的涨跌幅
(C-REF(C,1))/REF(C,1)*100;
-------------------------------------------------------------------------------
0028--振幅
(H-L)/L*100;
-------------------------------------------------------------------------------
0029--均线金叉
CROSS(MA(C,N),MA(C,M));{N< M}
-------------------------------------------------------------------------------
0030--均线死叉
CROSS(MA(C,M),MA(C,N));{N< M}
-------------------------------------------------------------------------------
0031--均线多头排列
A1:=MA(C,N1);
A2:=MA(C,N2);
A3:=MA(C,N3);
A4:=MA(C,N4);
COUNT(A1>A2 AND A2>A3 AND A3>A4,3);
-------------------------------------------------------------------------------
0032--均线空头排列
A1:=MA(C,N1);
A2:=MA(C,N2);
A3:=MA(C,N3);
A4:=MA(C,N4);
COUNT(A1< A2 AND A2< A3 AND A3< A4,3);
-------------------------------------------------------------------------------
0033--N日均线向下
AA:=MA(C,N);
BB:=REF(AA,1);
AA< BB
-------------------------------------------------------------------------------
0034--N日均线向上
AA:=MA(C,N);
BB:=REF(AA,1);
AA>BB
-------------------------------------------------------------------------------
0035--N日均线走平
AA:=MA(C,N);
BB:=REF(AA,1);
AA=BB
-------------------------------------------------------------------------------
0036--向前N日至M日出现过均线死叉（P1< P2）
AA:=MA(C,P1);
BB:=MA(C,P2);
CC:=REF(CROSS(BB,AA),N);
COUNT(CC,M);
-------------------------------------------------------------------------------
0037--今日成交量大于N日以来的均量
VOL>MA(VOL,N);
-------------------------------------------------------------------------------
0038--低位密集
A1:=COST(85);
A2:=COST(15);
A3:=A1-A2;
A4:=(A1+A2)/2;
A5:=A3/A4*100<10;
B1:=HHV(H,120);
B2:=LLV(L,120);
B3:=B1-B2;
B4:=(A4-B2)< B3/2;
A5 AND B4;
-------------------------------------------------------------------------------
0039--换手率
VOL/CAPITAL*100;
-------------------------------------------------------------------------------
0040--N日盈亏
V1:=VOL/SUM(VOL,N);
V2:=DMA(CLOSE,V1);
V3:(CLOSE-V2)/V2*100;
-------------------------------------------------------------------------------
0041--曲线叠加
指标线的叠加，是为了方便观看和比较，没什么其他的意义。
一、对指标曲线的变化幅度放大
此法，一线变形，另一线不变，但变形线的走势与原线完全相似。
举例：C叠加V
BC:=HHV(C,N)-LLV(C,N);//N一般取常用主图上的K线数量
BV:=HHV(V,N);
BI:=BC/BV;//叠加比
B:=BI[DATACOUNT];//最后一根K线的叠加比，保证叠加比前后统一
成交量:V,VOLSTICK;
F:=C/REF(C,1);
JC:=REF(C,1)*(1+A*F)*B/A;//A－放大倍数，将C的涨跌幅度F放大
JL:=LLV(JC,N);//平移量。请去掉JC句的＝看JL的作用
收盘价:C,LINETHICK0,COLORYELLOW;//只显示数值，不画线
PARTLINE(C>0,JC-JL[DATACOUNT]),COLORYELLOW;//收盘价趋势线，只画线，不显示数值
通式：
曲线X叠加曲线Y
BX:=HHV(X,N)-LLV(X,N);
BY:=HHV(Y,N)-LLV(Y,N);
BI:=BX/BY;
B:=BI[DATACOUNT];
FX:=X/REF(X,1);
JX:=REF(X,1)*(1+A*FX)*B/A;
XL:=LLV(JX,N);
曲线Y:Y;
曲线X:X,LINETHICK0;//曲线X的值
PARTLINE(C,JX-XL[DATACOUNT]);//曲线X的线
二、百分比叠加
把两曲线的波动幅度划成百分比进行叠加
此法，两线都变形，但走势都与原线完全相似。
举例：C叠加V
HV:=HHV(V,N);
DV:=HV[DATACOUNT];
BV:=100/DV;
V*BV,VOLSTICK;
HC:=HHV(C,N);
LC:=LLV(C,N);
BC:=100/(HC[DATACOUNT]-LC[DATACOUNT]);
(C-LC[DATACOUNT])*BC;
通式一：
曲线X，曲线Y
XH:=HHV(X,N);
XL:=LLV(X,N);
XDH:=XH[DATACOUNT];
XDL:=XL[DATACOUNT];
BX:=100/(XDH-XDL);
曲线X:(X-XDL)*BX;
YH:=HHV(Y,N);
YL:=LLV(Y,N);
YDH:=YH[DATACOUNT];
YDL:=YL[DATACOUNT];
BY:=100/(YDH-YDL);
曲线Y:(Y-YDL)*BY;
通式二：
X曲线+Y曲线
N:=SYSPARAM(3)-SYSPARAM(2);
X:=.........; {.........为X曲线定义}
XH:=HHV(X,N);
XL:=LLV(X,N);
XDH:=XH[SYSPARAM(3)];
XDL:=XL[SYSPARAM(3)];
BX:=100/(XDH-XDL);
曲线X:(X-XDL)*BX;
Y:=.........;{.........为Y曲线定义}
YH:=HHV(Y,N);
YL:=LLV(Y,N);
YDH:=YH[SYSPARAM(3)];
YDL:=YL[SYSPARAM(3)];
BY:=100/(YDH-YDL);
曲线Y:(Y-YDL)*BY;
三、固定位置叠加
此法应用不多，仅举例。
例一：
主图成交量(V叠加C)
{M:960,1,2000}
R0:=M/1000;R:=(L-R0*SYSPARAM(5))/V;
R1:=LLV(R,SYSPARAM(3)-SYSPARAM(2));R2:=R1[SYSPARAM(3)];
R3:=LLV(L-R2*V,SYSPARAM(3)-SYSPARAM(2));
R4:=R3[SYSPARAM(3)];R5:=(R2*V+R4)*0.995;
STICKLINE(C>=REF(C,1),R5,R0*SYSPARAM(5),6,1)COLORRED;
STICKLINE(C< REF(C,1),R5,R0*SYSPARAM(5),6,0)COLORCYAN;
PARTLINE(V>=0,R0*SYSPARAM(5)) COLORWHITE;
PARTLINE(R5>0,MA(R5,5));
PARTLINE(R5>0,MA(R5,10));
PARTLINE(R5>0,MA(R5,20));
例二：
INPUT:N(10,2,999);
M:=SYSPARAM(3)-SYSPARAM(2);
X:=C;
Y:=SUM(IF(CLOSE>REF(CLOSE,1),VOL/CAPITAL,IF(CLOSE< REF(CLOSE,1),-VOL/CAPITAL,0)),0);
XH:=HHV(X,M); XL:=LLV(X,M); XDH:=XH[SYSPARAM(3)]; XDL:=XL[SYSPARAM(3)];
BX:=100/(XDH-XDL);
收盘:C,LINETHICK0,;
收盘↑:PARTLINE(X>REF(X,1),(X-XDL)*BX),COLORRED;
收盘↓:PARTLINE(X< REF(X,1),(X-XDL)*BX),COLORCYAN;
YH:=HHV(Y,M); YL:=LLV(Y,M); YDH:=YH[SYSPARAM(3)]; YDL:=YL[SYSPARAM(3)];
BY:=100/(YDH-YDL);
TY:=(Y-YDL)*BY;
OBV值:Y*1000,LINETHICK0,COLOR007BFF;
OBV线↑:PARTLINE(Y>REF(Y,1),(Y-YDL)*BY),COLORYELLOW;
OBV线↓:PARTLINE(Y< REF(Y,1),(Y-YDL)*BY),COLOR009F00;
A1:=REF(TY,N)=HHV(TY,2*N+1); B1:=FILTER(A1,N); C1:=BACKSET(B1,N+1); HD:=FILTER(C1,N);
A2:=REF(TY,N)=LLV(TY,2*N+1); B2:=FILTER(A2,N); C2:=BACKSET(B2,N+1); LD:=FILTER(C2,N);
AA:=REF(TY,BARSLAST(HD)); BB:=REF(TY,BARSLAST(LD));A1:=REF(Y,BARSLAST(HD))*1000; B1:=REF(Y,BARSLAST(LD))*1000;
T1:=BARSLAST(HD)< BARSLAST(LD) AND NOT(HD) ;
T2:=BARSLAST(HD)>BARSLAST(LD) AND NOT(LD);
PARTLINE(T1,AA),COLORMAGENTA,LINETHICK2;
PARTLINE(T2,BB),COLORGREEN,LINETHICK2;
DRAWNUMBER(T1=0 AND REF(T1,1)>0,REF(AA,1)+0.1,A1,2);
DRAWNUMBER(T2=0 AND REF(T2,1)>0,REF(BB,1)+0.1,B1,2);
DRAWNUMBER(ISLASTBAR AND T1>0,REF(AA,1)+0.1,A1,2),COLORYELLOW;
DRAWNUMBER(ISLASTBAR AND T2>0,REF(BB,1)+0.1,B1,2),COLORMAGENTA;
-------------------------------------------------------------------------------
0042--均线变色
MA05:MA(CLOSE,5);
MA30:MA(CLOSE,30);
IF(MA05< MA30,MA05,MA30),COLORGREEN;
IF(MA05< MA30,MA30,MA05),COLORRED;
IF(MA05>MA30,MA30,MA30),COLORBLUE;
DRAWICON(CROSS(MA05,MA30),L*0.98,4);
DRAWICON(CROSS(MA30,MA05),H*1.02,5);
-------------------------------------------------------------------------------
0043--基本配色：白红峰
白红峰 ((16色)白色-红色)
VarA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VarA,0),6,1)/SMA(ABS(CLOSE-VarA),6,1)*100);
STICKLINE(色彩峰>0,0,色彩峰,5,0),COLORFFFFFF;{白色}
STICKLINE(色彩峰>0,0,色彩峰*0.9,5,0),COLOREEEEFF;
STICKLINE(色彩峰>0,0,色彩峰*0.85,5,0),COLORDDDDFF;
STICKLINE(色彩峰>0,0,色彩峰*0.8,5,0),COLORCCCCFF;
STICKLINE(色彩峰>0,0,色彩峰*0.75,5,0),COLORBBBBFF;
STICKLINE(色彩峰>0,0,色彩峰*0.7,5,0),COLORAAAAFF;
STICKLINE(色彩峰>0,0,色彩峰*0.65,5,0),COLOR9999FF;
STICKLINE(色彩峰>0,0,色彩峰*0.6,5,0),COLOR8888FF;
STICKLINE(色彩峰>0,0,色彩峰*0.55,5,0),COLOR7777FF;
STICKLINE(色彩峰>0,0,色彩峰*0.5,5,0),COLOR6666FF;
STICKLINE(色彩峰>0,0,色彩峰*0.45,5,0),COLOR5555FF;
STICKLINE(色彩峰>0,0,色彩峰*0.4,5,0),COLOR4444FF;
STICKLINE(色彩峰>0,0,色彩峰*0.35,5,0),COLOR3333FF;
STICKLINE(色彩峰>0,0,色彩峰*0.3,5,0),COLOR2222FF;
STICKLINE(色彩峰>0,0,色彩峰*0.25,5,0),COLOR1111FF;
STICKLINE(色彩峰>0,0,色彩峰*0.2,5,0),COLOR0000FF;{红色}
-------------------------------------------------------------------------------
0044--基本配色：白晶峰
白晶峰 ((16色)白色-晶红色)
VarA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VarA,0),6,1)/SMA(ABS(CLOSE-VarA),6,1)*100);
STICKLINE(色彩峰>0,0,色彩峰,5,0),COLORFFFFFF;{白色}
STICKLINE(色彩峰>0,0,色彩峰*0.9,5,0),COLORFFEEFF;
STICKLINE(色彩峰>0,0,色彩峰*0.85,5,0),COLORFFDDFF;
STICKLINE(色彩峰>0,0,色彩峰*0.8,5,0),COLORFFCCFF;
STICKLINE(色彩峰>0,0,色彩峰*0.75,5,0),COLORFFBBFF;
STICKLINE(色彩峰>0,0,色彩峰*0.7,5,0),COLORFFAAFF;
STICKLINE(色彩峰>0,0,色彩峰*0.65,5,0),COLORFF99FF;
STICKLINE(色彩峰>0,0,色彩峰*0.6,5,0),COLORFF88FF;
STICKLINE(色彩峰>0,0,色彩峰*0.55,5,0),COLORFF77FF;
STICKLINE(色彩峰>0,0,色彩峰*0.5,5,0),COLORFF66FF;
STICKLINE(色彩峰>0,0,色彩峰*0.45,5,0),COLORFF55FF;
STICKLINE(色彩峰>0,0,色彩峰*0.4,5,0),COLORFF44FF;
STICKLINE(色彩峰>0,0,色彩峰*0.35,5,0),COLORFF33FF;
STICKLINE(色彩峰>0,0,色彩峰*0.3,5,0),COLORFF22FF;
STICKLINE(色彩峰>0,0,色彩峰*0.25,5,0),COLORFF11FF;
STICKLINE(色彩峰>0,0,色彩峰*0.2,5,0),COLORFF00FF;{晶红色}
-------------------------------------------------------------------------------
0045--基本配色：白蓝峰
白蓝峰 ((16色)白色-蓝色)
VarA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VarA,0),6,1)/SMA(ABS(CLOSE-VarA),6,1)*100);
STICKLINE(色彩峰>0,0,色彩峰,5,0),COLORFFFFFF;{白色}
STICKLINE(色彩峰>0,0,色彩峰*0.9,5,0),COLORFFEEEE;
STICKLINE(色彩峰>0,0,色彩峰*0.85,5,0),COLORFFDDDD;
STICKLINE(色彩峰>0,0,色彩峰*0.8,5,0),COLORFFCCCC;
STICKLINE(色彩峰>0,0,色彩峰*0.75,5,0),COLORFFBBBB;
STICKLINE(色彩峰>0,0,色彩峰*0.7,5,0),COLORFFAAAA;
STICKLINE(色彩峰>0,0,色彩峰*0.65,5,0),COLORFF9999;
STICKLINE(色彩峰>0,0,色彩峰*0.6,5,0),COLORFF8888;
STICKLINE(色彩峰>0,0,色彩峰*0.55,5,0),COLORFF7777;
STICKLINE(色彩峰>0,0,色彩峰*0.5,5,0),COLORFF6666;
STICKLINE(色彩峰>0,0,色彩峰*0.45,5,0),COLORFF5555;
STICKLINE(色彩峰>0,0,色彩峰*0.4,5,0),COLORFF4444;
STICKLINE(色彩峰>0,0,色彩峰*0.35,5,0),COLORFF3333;
STICKLINE(色彩峰>0,0,色彩峰*0.3,5,0),COLORFF2222;
STICKLINE(色彩峰>0,0,色彩峰*0.25,5,0),COLORFF1111;
STICKLINE(色彩峰>0,0,色彩峰*0.2,5,0),COLORFF0000;{蓝色}
-------------------------------------------------------------------------------
0046--基本配色：白绿峰
白绿峰 ((16色)白色-绿色)
VarA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VarA,0),6,1)/SMA(ABS(CLOSE-VarA),6,1)*100);
STICKLINE(色彩峰>0,0,色彩峰,5,0),COLORFFFFFF;{白色}
STICKLINE(色彩峰>0,0,色彩峰*0.9,5,0),COLOREEFFEE;
STICKLINE(色彩峰>0,0,色彩峰*0.85,5,0),COLORDDFFDD;
STICKLINE(色彩峰>0,0,色彩峰*0.8,5,0),COLORCCFFCC;
STICKLINE(色彩峰>0,0,色彩峰*0.75,5,0),COLORBBFFBB;
STICKLINE(色彩峰>0,0,色彩峰*0.7,5,0),COLORAAFFAA;
STICKLINE(色彩峰>0,0,色彩峰*0.65,5,0),COLOR99FF99;
STICKLINE(色彩峰>0,0,色彩峰*0.6,5,0),COLOR88FF88;
STICKLINE(色彩峰>0,0,色彩峰*0.55,5,0),COLOR77FF77;
STICKLINE(色彩峰>0,0,色彩峰*0.5,5,0),COLOR66FF66;
STICKLINE(色彩峰>0,0,色彩峰*0.45,5,0),COLOR55FF55;
STICKLINE(色彩峰>0,0,色彩峰*0.4,5,0),COLOR44FF44;
STICKLINE(色彩峰>0,0,色彩峰*0.35,5,0),COLOR33FF33;
STICKLINE(色彩峰>0,0,色彩峰*0.3,5,0),COLOR22FF22;
STICKLINE(色彩峰>0,0,色彩峰*0.25,5,0),COLOR11FF11;
STICKLINE(色彩峰>0,0,色彩峰*0.2,5,0),COLOR00FF00;{绿色}
-------------------------------------------------------------------------------
0047--基本配色：淡紫峰
淡紫峰 ((16色)淡蓝色-紫色)
VarA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VarA,0),6,1)/SMA(ABS(CLOSE-VarA),6,1)*100);
STICKLINE(色彩峰>0,0,色彩峰,5,0),COLORFFFFCC;{淡蓝色}
STICKLINE(色彩峰>0,0,色彩峰*0.9,5,0),COLORFFEECC;
STICKLINE(色彩峰>0,0,色彩峰*0.85,5,0),COLORFFDDCC;
STICKLINE(色彩峰>0,0,色彩峰*0.8,5,0),COLORFFCCCC;
STICKLINE(色彩峰>0,0,色彩峰*0.75,5,0),COLORFFBBCC;
STICKLINE(色彩峰>0,0,色彩峰*0.7,5,0),COLORFFAACC;
STICKLINE(色彩峰>0,0,色彩峰*0.65,5,0),COLORFF99CC;
STICKLINE(色彩峰>0,0,色彩峰*0.6,5,0),COLORFF88CC;
STICKLINE(色彩峰>0,0,色彩峰*0.55,5,0),COLORFF77CC;
STICKLINE(色彩峰>0,0,色彩峰*0.5,5,0),COLORFF66CC;
STICKLINE(色彩峰>0,0,色彩峰*0.45,5,0),COLORFF55CC;
STICKLINE(色彩峰>0,0,色彩峰*0.4,5,0),COLORFF44CC;
STICKLINE(色彩峰>0,0,色彩峰*0.35,5,0),COLORFF33CC;
STICKLINE(色彩峰>0,0,色彩峰*0.3,5,0),COLORFF22CC;
STICKLINE(色彩峰>0,0,色彩峰*0.25,5,0),COLORFF11CC;
STICKLINE(色彩峰>0,0,色彩峰*0.2,5,0),COLORFF00CC;{紫色}
-------------------------------------------------------------------------------
0048--基本配色：黄褐峰
黄褐峰 ((16色)黄色-绿色-褐色)
VarA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VarA,0),6,1)/SMA(ABS(CLOSE-VarA),6,1)*100);
STICKLINE(色彩峰>0,0,色彩峰,5,0),COLOR00FFFF;{黄色}
STICKLINE(色彩峰>0,0,色彩峰*0.9,5,0),COLOR00FFEE;
STICKLINE(色彩峰>0,0,色彩峰*0.85,5,0),COLOR00FFDD;
STICKLINE(色彩峰>0,0,色彩峰*0.8,5,0),COLOR00FFCC;
STICKLINE(色彩峰>0,0,色彩峰*0.75,5,0),COLOR00FFBB;
STICKLINE(色彩峰>0,0,色彩峰*0.7,5,0),COLOR00FFAA;
STICKLINE(色彩峰>0,0,色彩峰*0.65,5,0),COLOR00FF99;{绿色}
STICKLINE(色彩峰>0,0,色彩峰*0.6,5,0),COLOR00EE99;
STICKLINE(色彩峰>0,0,色彩峰*0.55,5,0),COLOR00DD99;
STICKLINE(色彩峰>0,0,色彩峰*0.5,5,0),COLOR00CC99;
STICKLINE(色彩峰>0,0,色彩峰*0.45,5,0),COLOR00BB99;
STICKLINE(色彩峰>0,0,色彩峰*0.4,5,0),COLOR00AA99;
STICKLINE(色彩峰>0,0,色彩峰*0.35,5,0),COLOR009999;
STICKLINE(色彩峰>0,0,色彩峰*0.3,5,0),COLOR008899;
STICKLINE(色彩峰>0,0,色彩峰*0.25,5,0),COLOR007799;
STICKLINE(色彩峰>0,0,色彩峰*0.2,5,0),COLOR006699;{褐色}
-------------------------------------------------------------------------------
0049--基本配色：黄红峰
黄红峰 ((16色)黄色-红色)
VarA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VarA,0),6,1)/SMA(ABS(CLOSE-VarA),6,1)*100);
STICKLINE(色彩峰>0,0,色彩峰,5,0),COLOR00FFFF;{黄色}
STICKLINE(色彩峰>0,0,色彩峰*0.9,5,0),COLOR00EEFF;
STICKLINE(色彩峰>0,0,色彩峰*0.85,5,0),COLOR00DDFF;
STICKLINE(色彩峰>0,0,色彩峰*0.8,5,0),COLOR00CCFF;
STICKLINE(色彩峰>0,0,色彩峰*0.75,5,0),COLOR00BBFF;
STICKLINE(色彩峰>0,0,色彩峰*0.7,5,0),COLOR00AAFF;
STICKLINE(色彩峰>0,0,色彩峰*0.65,5,0),COLOR0099FF;
STICKLINE(色彩峰>0,0,色彩峰*0.6,5,0),COLOR0088FF;
STICKLINE(色彩峰>0,0,色彩峰*0.55,5,0),COLOR0077FF;
STICKLINE(色彩峰>0,0,色彩峰*0.5,5,0),COLOR0066FF;
STICKLINE(色彩峰>0,0,色彩峰*0.45,5,0),COLOR0055FF;
STICKLINE(色彩峰>0,0,色彩峰*0.4,5,0),COLOR0044FF;
STICKLINE(色彩峰>0,0,色彩峰*0.35,5,0),COLOR0033FF;
STICKLINE(色彩峰>0,0,色彩峰*0.3,5,0),COLOR0022FF;
STICKLINE(色彩峰>0,0,色彩峰*0.25,5,0),COLOR0011FF;
STICKLINE(色彩峰>0,0,色彩峰*0.2,5,0),COLOR0000FF;{红色}
-------------------------------------------------------------------------------
0050--基本配色：黄绿峰
黄绿峰 ((16色)黄色-绿色)
VarA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VarA,0),6,1)/SMA(ABS(CLOSE-VarA),6,1)*100);
STICKLINE(色彩峰>0,0,色彩峰,5,0),COLOR00FFFF;{黄色}
STICKLINE(色彩峰>0,0,色彩峰*0.9,5,0),COLOR00FFEE;
STICKLINE(色彩峰>0,0,色彩峰*0.85,5,0),COLOR00FFDD;
STICKLINE(色彩峰>0,0,色彩峰*0.8,5,0),COLOR00FFCC;
STICKLINE(色彩峰>0,0,色彩峰*0.75,5,0),COLOR00FFBB;
STICKLINE(色彩峰>0,0,色彩峰*0.7,5,0),COLOR00FFAA;
STICKLINE(色彩峰>0,0,色彩峰*0.65,5,0),COLOR00FF99;
STICKLINE(色彩峰>0,0,色彩峰*0.6,5,0),COLOR00FF88;
STICKLINE(色彩峰>0,0,色彩峰*0.55,5,0),COLOR00FF77;
STICKLINE(色彩峰>0,0,色彩峰*0.5,5,0),COLOR00FF66;
STICKLINE(色彩峰>0,0,色彩峰*0.45,5,0),COLOR00FF55;
STICKLINE(色彩峰>0,0,色彩峰*0.4,5,0),COLOR00FF44;
STICKLINE(色彩峰>0,0,色彩峰*0.35,5,0),COLOR00FF33;
STICKLINE(色彩峰>0,0,色彩峰*0.3,5,0),COLOR00FF22;
STICKLINE(色彩峰>0,0,色彩峰*0.25,5,0),COLOR00FF11;
STICKLINE(色彩峰>0,0,色彩峰*0.2,5,0),COLOR00FF00;{绿色}
-------------------------------------------------------------------------------
0051--基本配色：灰色峰
灰色峰 ((16色)白色-黑色)
VarA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VarA,0),6,1)/SMA(ABS(CLOSE-VarA),6,1)*100);
STICKLINE(色彩峰>0,0,色彩峰,5,0),COLORFFFFFF;{白色}
STICKLINE(色彩峰>0,0,色彩峰*0.9,5,0),COLOREEEEEE;
STICKLINE(色彩峰>0,0,色彩峰*0.85,5,0),COLORDDDDDD;
STICKLINE(色彩峰>0,0,色彩峰*0.8,5,0),COLORCCCCCC;
STICKLINE(色彩峰>0,0,色彩峰*0.75,5,0),COLORBBBBBB;
STICKLINE(色彩峰>0,0,色彩峰*0.7,5,0),COLORAAAAAA;
STICKLINE(色彩峰>0,0,色彩峰*0.65,5,0),COLOR999999;
STICKLINE(色彩峰>0,0,色彩峰*0.6,5,0),COLOR888888;
STICKLINE(色彩峰>0,0,色彩峰*0.55,5,0),COLOR777777;
STICKLINE(色彩峰>0,0,色彩峰*0.5,5,0),COLOR666666;
STICKLINE(色彩峰>0,0,色彩峰*0.45,5,0),COLOR555555;
STICKLINE(色彩峰>0,0,色彩峰*0.4,5,0),COLOR444444;
STICKLINE(色彩峰>0,0,色彩峰*0.35,5,0),COLOR333333;
STICKLINE(色彩峰>0,0,色彩峰*0.3,5,0),COLOR222222;
STICKLINE(色彩峰>0,0,色彩峰*0.25,5,0),COLOR111111;
STICKLINE(色彩峰>0,0,色彩峰*0.2,5,0),COLOR000000;{黑色}
-------------------------------------------------------------------------------
0052--基本配色：绿蓝峰
绿蓝峰 ((16色)翠绿-深蓝)
VarA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VarA,0),6,1)/SMA(ABS(CLOSE-VarA),6,1)*100);
STICKLINE(色彩峰>0,0,色彩峰,5,0),COLOR66FF00;{翠绿}
STICKLINE(色彩峰>0,0,色彩峰*0.9,5,0),COLOR66EE00;
STICKLINE(色彩峰>0,0,色彩峰*0.85,5,0),COLOR66DD00;
STICKLINE(色彩峰>0,0,色彩峰*0.8,5,0),COLOR66CC00;
STICKLINE(色彩峰>0,0,色彩峰*0.75,5,0),COLOR66BB00;
STICKLINE(色彩峰>0,0,色彩峰*0.7,5,0),COLOR66AA00;
STICKLINE(色彩峰>0,0,色彩峰*0.65,5,0),COLOR669900;
STICKLINE(色彩峰>0,0,色彩峰*0.6,5,0),COLOR668800;
STICKLINE(色彩峰>0,0,色彩峰*0.55,5,0),COLOR667700;
STICKLINE(色彩峰>0,0,色彩峰*0.5,5,0),COLOR666600;
STICKLINE(色彩峰>0,0,色彩峰*0.45,5,0),COLOR665500;
STICKLINE(色彩峰>0,0,色彩峰*0.4,5,0),COLOR664400;
STICKLINE(色彩峰>0,0,色彩峰*0.35,5,0),COLOR663300;
STICKLINE(色彩峰>0,0,色彩峰*0.3,5,0),COLOR662200;
STICKLINE(色彩峰>0,0,色彩峰*0.25,5,0),COLOR661100;
STICKLINE(色彩峰>0,0,色彩峰*0.2,5,0),COLOR660000;{深蓝}
-------------------------------------------------------------------------------
0053--随机K线最高、最低价向右平行线
DRAWSL(SYSPARAM(1)=BARPOS,REF(L,SYSPARAM(1)=SUM(1,0)-1),0,0,1),COLORGREEN;
DRAWSL(SYSPARAM(1)=BARPOS,REF(H,SYSPARAM(1)=SUM(1,0)-1),0,0,1),COLORRED;
-------------------------------------------------------------------------------
0054--显示无数条线
例一：
{先显示200条黄色的}
A1:POLYLINE(C>0,C+0.01),COLORYELLOW;
A2:=POLYLINE(C>0,C+0.02);
A3:=POLYLINE(C>0,C+0.03);
……
A199:=POLYLINE(C>0,C+1.99):
A200:POLYLINE(C>0,C+2) COLORYELLOW;
{再显示200条绿色的}
B1:POLYLINE(C>0,C+2.01) COLORGREEN;
B2:=POLYLINE(C>0,C+2.02) ;
B3:=POLYLINE(C>0,C+2.03) ;
……
B199:=POLYLINE(C>0,C+3.99):
B200:POLYLINE(C>0,C+4) COLORGREEN;
{想显示别的颜色继续……}
例二：
{先显示200条黄色的}
A1:=POLYLINE(C>0,C+0.01);
A2:=POLYLINE(C>0,C+0.02);
A3:=POLYLINE(C>0,C+0.03);
……
A199:=POLYLINE(C>0,C+1.99);
A200:=POLYLINE(C>0,C+2);
A1 OR A2 OR A3 OR……OR A199 OR A200,COLORYELLOW;
{再显示200条绿色的}
B1:=POLYLINE(C>0,C+2.01);
B2:=POLYLINE(C>0,C+2.02) ;
B3:=POLYLINE(C>0,C+2.03) ;
……
B199:=POLYLINE(C>0,C+3.99):
B200:=POLYLINE(C>0,C+4) ;
B1 OR B2 OR B3 OR……OR B199 OR B200,COLORGREEN;
{想显示别的颜色继续……}
-------------------------------------------------------------------------------
0055--底背离
LLV(L,60)=L) AND NOT(LLV(DEA,60)=DEA);
-------------------------------------------------------------------------------
0056--顶背离
HHV(H,60)=H) AND NOT(HHV(DEA,60)=DEA);
-------------------------------------------------------------------------------
0057--N次金叉、死叉
0轴上二次金叉
COUNT(CROSS(DIF,DEA) AND DEA>0,20)=2 AND CROSS(DIF,DEA) AND
DEA>0;
0轴上三次金叉
COUNT(CROSS(DIF,DEA) AND DEA>0,20)=3 AND CROSS(DIF,DEA) AND
DEA>0;
0轴上四次金叉
COUNT(CROSS(DIF,DEA) AND DEA>0,20)=4 AND CROSS(DIF,DEA) AND DEA>0;
二次金叉
EXPLAIN(COUNT(CROSS(DIF,DEA),20)=2 AND CROSS(DIF,DEA);
二次死叉
COUNT(CROSS(DEA,DIF),20)=2 AND CROSS(DEA,DIF);
-------------------------------------------------------------------------------
0058--5分钟副图显示15分钟K线
建公式:0015
C15:CLOSE;
O15:OPEN;
H15:HIGH;
L15:LOW;
建公式:十五K线
C15:="0015.C15#MIN15";
O15:="0015.O15#MIN15";
H15:="0015.H15#MIN15";
L15:="0015.L15#MIN15";
TI:=OPENMINUTES(TIME)=10 OR OPENMINUTES(TIME)=25 OR OPENMINUTES(TIME)=40 OR OPENMINUTES(TIME)=55 OR OPENMINUTES(TIME)=70 OR OPENMINUTES(TIME)=85 OR OPENMINUTES(TIME)=100 OR OPENMINUTES(TIME)=115 OR OPENMINUTES(TIME)=130 OR OPENMINUTES(TIME)=145 OR OPENMINUTES(TIME)=160 OR OPENMINUTES(TIME)=175 OR OPENMINUTES(TIME)=190 OR OPENMINUTES(TIME)=205 OR OPENMINUTES(TIME)=220 OR OPENMINUTES(TIME)=235;
HH15:=IF(TI,H15,C15);
LL15:=IF(TI,L15,C15);
STICKLINE(C15>O15,C15,O15,10,0),COLORRED;
STICKLINE(C15>O15 AND H15>C15,HH15,C15,0.1,0),COLORRED;
STICKLINE(C15>O15 AND O15>L15,O15,LL15,0.1,0),COLORRED;
STICKLINE(C15<=O15,C15,O15,10,0),COLORGREEN;
STICKLINE(C15<=O15 AND C15>L15,C15,LL15,0.1,0),COLORGREEN;
STICKLINE(C15<=O15 AND H15>O15,HH15,O15,0.1,0),COLORGREEN;
注：以大陆股市为例，四小时，其他市场如超过四小时，可在中间语句“TI:=”中以15为系数顺序加足，如：OR 250 OR 265……等等。
-------------------------------------------------------------------------------
0059--移动成本
不知道函数算法，计算误差在所难免。调整参数“％”可看到不同的移动成本。
///筹码%
INPUT:%(90,1,100);
A:=AMOUNT/V/100;
成本:FLOOR(COST(50-%/2)*100)/100,COLORYELLOW,LINETHICK0;
～:CEILING(COST(50+%/2)*100)/100,COLORYELLOW,LINETHICK0;
集中度:INTPART((～-成本)/(～+成本)*1000)/10,COLORGREEN;
平均成本:ROUND(COST(50)*100)/100,LINETHICK0;
穿透力:(WINNER(C)-REF(WINNER(C),1))/V*CAPITAL,LINETHICK0;//计算误差大
//穿透力2:(WINNER(C)-WINNER(O))/V*CAPITAL,LINETHICK0;//这一写法还是误差大
获利比例:ROUND(WINNER(C)*1000)/10,LINETHICK0;
-------------------------------------------------------------------------------
0060--妙用SUMBARS()函数
SUMBARS(X,N)
函数的用法如下：
向前累加到指定值到现在的周期数。
用法:
SUMBARS(X,A)
将X向前累加直到大于等于A,返回这个区间的周期数
例如:
SUMBARS(VOL,CAPITAL)
1、设计一个指标，计算当日成交量是几天内的最高成交量？
2、设计一个指标，计算当日最高价是几天内的最高价？
提示：直接用HHV()函数无法得到正确结果。
例一：
B:=HHV(H,0);
A:=IF(BARPOS=1,B[DATACOUNT]*1.2,H);
价:SUMBARS(REF(A,1)-A,0);
U:=HHV(V,0);
S:=IF(BARPOS=1,U[DATACOUNT]*1.2,V);
量:SUMBARS(REF(S,1)-S,0);
或：
VH:=HHV(VOL,0);
FV:=IF(BARPOS=1,VH[DATACOUNT]*1.2,VOL); //VH[DATACOUNT]是历史最高成交量
量创新高周期数:SUMBARS(REF(FV,1)-FV,0);
{这里的关键是 REF(FV,1)-FV ，想想看写成 FV-REF(FV,1) 行不行？}
另一种写法：
VH:=HHV(VOL,0);
FV:=VOL;
FV[1]:=VH[DATACOUNT]*1.2; //VH[DATACOUNT]是历史最高成交量
量创新高周期数:SUMBARS(REF(FV,1)-FV,0);
{这里的关键是 REF(FV,1)-FV ，想想看写成 FV-REF(FV,1) 行不行？}
代码已经成功了，原理是什么呢？
假设某日成交量是3日内的最大成交量，则必有：
REF(VOL,3)-VOL>=0
等价于：
(REF(VOL,3)-REF(VOL,2))+(REF(VOL,2)-REF(VOL,1))+(REF(VOL,1)-VOL) >=0
意思就是说，“昨成交量与今成交量之差”逐日累加，直到某日累加和大于等于0，则这之间的天数，就是所要求的日数。
我们再来看看SUMBARS()函数的含义：
SUMBARS(X,A):将X向前累加直到大于等于A,返回这个区间的周期数。
显然上面的式子：
(REF(VOL,3)-REF(VOL,2))+(REF(VOL,2)-REF(VOL,1))+(REF(VOL,1)-VOL)>=0
可以写成：
SUMBARS(REF(VOL,1)-VOL, 0);
为何第1周期的成交量要替换成比所有成交量都大的数值？最后，再来思考一个问题，把题目中的求“最大”，改成求“最小”，即多少天内是最小的？
例二：
B:=HHV(H,0);
A:=IF(BARPOS=1,9999,H);
Z:SUMBARS(REF(A,1)-A,0);
DRAWNUMBER(BARPOS=SYSPARAM(1),1,Z,0)ALIGN4,COLORWHITE;
U:=HHV(V,0);
S:=IF(BARPOS=1,999999999999,V)
Y:SUMBARS(REF(S,1)-S,0);
DRAWNUMBER(BARPOS=SYSPARAM(1),1,Y,0)ALIGN3,COLORYELLOW;
例三：
HH:=IF(BARSCOUNT(C)=1,9999,H);
ZH:SUMBARS(REF(HH,1)-HH,0);//价创了N周期新高
VH:=IF(BARSCOUNT(C)=1,99999999,V);
HV:SUMBARS(REF(VH,1)-VH,0);//量创了N周期新高
LL:=IF(BARSCOUNT(C)=1,0,L);
ZL:SUMBARS(LL-REF(LL,1),0);//价创了N周期新低
VL:=IF(BARSCOUNT(C)=1,0,V);
LV:SUMBARS(VL-REF(VL,1),0);//量创了N周期新低
附注：
用99999999等具体数值，最好是尽可能大的数值（比如单精数的上限），否则仍有可能无法全部完成计算，比如上证指数的年线，成交量最大时，仍然超过了99999999。
倒数第6天的最高价格怎么表示？
FH:=HIGH;
FH[DATACOUNT-5]; //倒数第6天的最高价格。
[DATACOUNT]
返回K线的数量，即总共有多少根K线。
-------------------------------------------------------------------------------
0061--取得K线的序号
取得K线的序号，正序有下面几种方法：(从1数起)
BARPOS;
SX:BARSCOUNT(CLOSE);
SY:SUM(1,0);
DATACOUNT;{不随光标变动，只显示最后K线序号}
逆序可用下列方法取得：(从1数起)
(DATACOUNT-BARPOS)+1;
(DATACOUNT-BARSCOUNT(CLOSE))+1;
(DATACOUNT-SUM(1,0))+1;
-------------------------------------------------------------------------------
0062--变量宣告
指定叙述：经过指定宣告后，飞狐才认识AA、BB、CC，否则会出现"未定义的标示符号"。所谓"定义"，程序语言的用语，就叫做"变量宣告"。
AA:OPEN;{宣告OPEN，指定给AA→输出的表达式}
BB:HIGH,LINETHICK0;{宣告HIGH，指定给BB→输出的表达式→秀数值但不秀线图}
CC:=CLOSE;{宣告CLOSE，指定给CC→不输出的表达式→不秀数值也不秀线图}
DD:(AA+BB+CC)/3;{;分号，告诉程序要换行执行了}
EE:=(AA+CC)/2;
PARTLINE(CLOSE>0,EE);{秀线图但不秀数值}
注：{ }大括号内或在//后面，可用来输入公式批注。
-------------------------------------------------------------------------------
0063--跨周期引用数据
(一)指针线公式的运算，大部份都是代入开、高、低、收、量等数据去运算的。
(二)开、高、低、收、量又分成下面四种型式出现：
开、高、低、收、量(基本的日K线数据)
开、高、低、收、量(周K线数据)
开、高、低、收、量(月K线数据)
开、高、低、收、量(年K线数据)
(三)所以当指针线公式运算，要代入下面数据时：
开、高、低、收、量(周K线数据)
开、高、低、收、量(月K线数据)
#WEEK 和 #MONTH 就会派上用场。
(四)举例：
公式A.建立一个专门被用来引用(QUOTE)的公式区。
公式名称：QU
A1:(OPEN+HIGH+LOW+CLOSE)/4;
说明：上面公式的运算，是代入开、高、低、收(当前周期K线数据)运算的。
公式B.
公式名称：AA
AA:"QU.A1#WEEK";
说明：将下面公式的运算，代入开、高、低、收(周K线数据)运算。
(OPEN+HIGH+LOW+CLOSE) / 4
公式C.
公式名称：BB
BB:"QU.A1#MONTH";
说明：将下面公式的运算，代入开、高、低、收(月K线数据)运算。
(OPEN+HIGH+LOW+CLOSE)/4
附注：
可供引用的周期类型有：
MIN1，MIN5，MIN15，MIN30，MIN60，DAY，WEEK，MONTH
分别表示将1，5，15，30，60分钟K线数据，以及日，周，月K线数据，代入被引用的公式，进行运算。
意义：
可将大周期内跑的数据，引用到小周期内来跑。将小周期内跑的数据，引用到大周期内来跑，就会有问题，因为时间横坐标不一样了。
公式(1)：先建立即将被引用的表达式
将公式建立在：技术指针 ( ●主图叠加 ○主图 )
公式名称：NH
AA:=HIGH< REF(HIGH,1);{不输出的表达式，如果被引用还是会变成不输出的表达式}
BB:=BARSLAST(AA=1);
CC:REF(HIGH,BB); {输出的表达式，如果被引用还是会变成输出的表达式}
说明：
上面公式的运算，是以当周期时间数列数据运算的。
公式(2)：
将公式建立在：技术指针 ( ●主图叠加 ○主图 )
公式名称：NHH
AA:"NH.AA#WEEK";{不输出的表达式}
BB:"NH.BB#WEEK";
CC:"NH.CC#WEEK";{输出的表达式}
DRAWNUMBER(ISLASTBAR,CC,CC,2);
说明：
上面公式的运算，是以周周期时间数列数据运算的。
-------------------------------------------------------------------------------
0064--未来数据、未知数据
写公式，首先要对已知数据(过去式)、未知数据(未完成式、现在进行式)有通盘的认知。
可将"未来"分为两种情况：
1、实时行情中：在一根K线。
以实时行情中的当前日K线为例。除了O之外，其它H、L、C全有未来之嫌。因为在收盘之前，拉高、打压是司空见惯的事，谁也不能保证H、L不会创出当天的新高和新低，更不用说C了。又如日线周期公式"C>REF(C,1);"，前一分钟信号成立，后一分钟可能信号就不成立了。另外，如引用了周K和月K数据，因为当前周K和月K还在变动之中，所以也是未来资料。
2、盘后中：在多根K线。
因为在盘后，日K中的四大要素O、H、L、C就没有未来之可能了。在盘后，除了周五之外，引用的周K指针也是未来数据。除了在月末，引用的月K指针也是未来数据。
总而言之，指针公式就分这两种：
线图信号的确定→全都用已知数据(过去式)来决定。
线图信号的确定→有用到未知数据(未完成式、现在进行式)来决定。
ZIG函数
ZX:ZIG(CLOSE,8);
最近这次峰点、谷点的确定，也常处在未完成式的状态中。
打个比喻，线图信号的确定→有用到未知数据(未完成式、现在进行式)，例如，在实时盘中一根日K线的收盘价变来变去，指针线图当然随之而起舞。
ZIG函数只是把格局放大，N的日K组合而成的一根多日K线，这一根多日K线的收盘价变来变去，指针线图当然随之而起舞。
-------------------------------------------------------------------------------
0065--主图KD
在主图上，坐标是以K线的价格为主。如何将在0与100中游走的KD指针附加上去，这是写作指针的基本逻辑观念的运用。
PARAM#1( N，9，2，100 )
PARAM#2( M1，3，1，40 )
PARAM#3( M2，3，1，40 )
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100 LINETHICK0;{:=运算过程不显示值与图}
K:SMA(RSV,3,1),LINETHICK0,COLORWHITE;{LINETHICK0只显值不显图}
D:SMA(K,3,1),LINETHICK0,COLORYELLOW;
HH:=SYSPARAM(4);{主图可见K线最高价}
LL:=SYSPARAM(5);{主图可见K线最低价}
KK:=K/100*(HH-LL)+LL;
DD:=D/100*(HH-LL)+LL;
PARTLINE(1=1,KK),COLORWHITE; {条件成立时，则显示图线形}
PARTLINE(C>0,DD),COLORYELLOW;
C;{显示收盘价的值与图线形}
PARTLINE(C>=REF(C,1),C),COLORRED;{显示收盘价的图改成涨红跌绿联机图}
PARTLINE(C< REF(C,1),C),COLORGREEN;
-------------------------------------------------------------------------------
0066--描绘K线
例一：普通
将下列公式建立在：技术指针 ( ○主图叠加 ●主图 )
公式名称：KL
STICKLINE( ISUP , HIGH , LOW , 0.1 , 0 ) , COLORRED ;
STICKLINE( ISUP , CLOSE , OPEN , 8 , 1 ) , COLORRED ;
STICKLINE( ISDOWN , HIGH , LOW , 0.1 , 0 ) , COLORCYAN ;
STICKLINE( ISDOWN , CLOSE , OPEN , 8 , 0 ) , COLORCYAN ;
STICKLINE( ISEQUAL AND C>REF( C , 1 ) , HIGH , LOW , 0.1 , 0 ) , COLORRED ;
STICKLINE( ISEQUAL AND C>REF( C , 1 ) , CLOSE , OPEN , 8 , 0 ) , COLORRED ;
STICKLINE( ISEQUAL AND C<=REF( C , 1 ) , HIGH , LOW , 0.1 , 0 ) , COLORCYAN ;
STICKLINE( ISEQUAL AND C<=REF( C , 1 ) , CLOSE , OPEN , 8 , 0 ) , COLORCYAN ;
X:=BARSCOUNT( CLOSE ) ;
{以下是描绘第一个交易日的K线，以补前面含盖的不足}
STICKLINE( ISEQUAL AND X = 1 , HIGH, LOW, 0.1, 0 ) , COLORRED ;
STICKLINE( ISEQUAL AND X = 1 , CLOSE , OPEN , 8 , 0 ) , COLORRED ;
说明：
ISUP函数：相当于 IF( CLOSE>OPEN , 1 , 0 )。
ISEQUAL函数：相当于 IF( CLOSE=OPEN , 1 , 0 )。
ISDOWN函数：相当于 IF( CLOSE < OPEN , 1 , 0 )。
STICKLINE函数，画出来的对象有重叠覆盖性：→后画的对象可覆盖先画的对象。
例二：配色
STICKLINE( ISUP , HIGH , LOW , 0.1 , 0 ),COLOR04FEFC ;
STICKLINE( ISUP , CLOSE , OPEN , 8 , 0 ),COLOR0466FC ;
STICKLINE( ISUP , CLOSE , OPEN , 3 , 0 ),COLOR04FEFC ;
STICKLINE( ISDOWN , HIGH , LOW , 0.1 , 0 ),COLORFCFE04 ;
STICKLINE( ISDOWN , CLOSE , OPEN , 8 , 0 ),COLORFC6604 ;
STICKLINE( ISDOWN , CLOSE , OPEN , 3 , 0 ),COLORFCFE04 ;
STICKLINE( ISEQUAL AND C>REF( C , 1 ) , HIGH , LOW , 0.1 , 0 ),COLOR04FEFC ;
STICKLINE( ISEQUAL AND C>REF( C , 1 ) , CLOSE , OPEN , 8 , 0 ),COLOR0466FC ;
STICKLINE( ISEQUAL AND C>REF( C , 1 ) , CLOSE , OPEN , 3 , 0 ),COLOR04FEFC ;
STICKLINE( ISEQUAL AND C<=REF( C , 1 ) , HIGH , LOW , 0.1 , 0 ),COLORFCFE04 ;
STICKLINE( ISEQUAL AND C<=REF( C , 1 ) , CLOSE , OPEN , 8 , 0 ),COLORFC6604 ;
STICKLINE( ISEQUAL AND C<=REF( C , 1 ) , CLOSE , OPEN , 3 , 0 ),COLORFCFE04 ;
X:=BARSCOUNT( CLOSE ) ;
{以下是描绘第一个交易日的K线，以补前面含盖的不足}
STICKLINE( ISEQUAL AND X = 1 , HIGH, LOW, 0.1, 0 ),COLOR04FEFC ;
STICKLINE( ISEQUAL AND X = 1 , CLOSE , OPEN , 8 , 1 ),COLOR0466FC ;
STICKLINE( ISEQUAL AND X = 1 , CLOSE , OPEN , 3 , 1 ),COLOR04FEFC ;
-------------------------------------------------------------------------------
0067--分时K线当天K线序号
范例：开盘第一根分时K线，指定一个值=1给它，其它为0。
XA:REF(DATE,1)<>DATE, STICK;
范例：每天的分时K线，指定它的当天K线序号给它
XA:=REF(DATE,1)<>DATE, STICK;
XB:BARSLAST(XA=1) + 1 ,STICK;
应用：每天在分时K线，累计成交张数
XA:=REF(DATE,1)<>DATE , STICK;
XB:=BARSLAST(XA=1) + 1 ,STICK;
SV:SUM( VOL , XB ) ;
范例：标记今天分时K线的今天K线序号。过了午夜12点，就又要等早盘开盘后序号数字才会出现
XA:=CURRENTDATE=DATE ;
XB:=REF(XA , 1)<>XA ;
XC:HHVBARS(XB , 0) + XA ;
应用：13均线今天当下最后数值向后延申，画平台线。
XA:=CURRENTDATE=DATE ;
XB:=REF(XA , 1)<>XA ;
XC:=HHVBARS(XB , 0) + XA ;
本站仅提供存储服务，所有内容均由用户发布，如发现有害或侵权内容，请
点击举报。
