Basic English Sentence Structures

The Predicate
The predicate is the part of the sentence that contains a verb or verb phrase and its complements.

<predicate> = (<verb> | <verb phrase>) <complement>

English has three main kinds of verbs: auxiliary verbs, linking verbs, and action verbs.
The verb "to be" is the most frequently used verb in English. Learn to use it correctly! Sometimes the verb "to be" is categorized as an auxiliary verb. The following list of auxiliary verbs excludes "be", "do", and "ought" because they have very different usage from other auxiliary verbs.

<auxV> = "must" | "may" |"might" |
       "will" |"would" |"shall" |
       "should" |"can" |"could"

The formal description of verbs uses verb forms starting with a "V" followed by an abbreviation with a number and a letter to represent the person and number. For example, "V1s" means Verb 1st person, singular. The abbreviations "Vinf", "Vpast", "Ving", "Vpastp", refer to the infinitive, past tense, present participle, and past participle forms of the verb, respectively.

Verb Conjugation
Action verbs constitute the majority of English verbs. The following table illustrates regular verb conjugation and the corresponding verb forms:

Infinitive (Vinf):		start
Present Participle (Ving):		starting
Past participle (Vpastp):		started
Person,Number		Present	Past (Vpast)
1st,singular	I	(V1s) start	started
2nd,singular	you	(V2s) start	started
3rd,singular	he/she/it	(V3s) starts	started
1st,plural	we	(V1p) start	started
2nd,plural	you	(V2p) start	started
3rd,plural	they	(V3p) start	started

Click here to conjugate over 7,400 regular and irregular English verbs.

<verb> = <V1s> |<V2s> |<V3s> |
       <V1p> |<V2p> |<V3p> |
       <Vpast> |<linking verb>

<linking verb> = "am" |"are" |"is" | "was"| "were" |
       "look" | "looks" | "looked" |
       "become" | "became" | "become" | ...

<verb phrase> =
       ("had" |"have" |"has") <Vpastp> |
       ("had" |"have" |"has") "been" [<Vpastp> | <Ving>] |
       <auxV> "have" <Vpastp> |
       <auxV> "have" "been" [<Vpastp> | <Ving>] |
       <auxV> "be" [<Vpastp> | <Ving>] |
       <auxV> <Vinf> |
       "ought" "to" <Vinf> |
       "ought" "to" "be" [<Vpastp> | <Ving>] |
       "ought" "to" "have" <Vpastp> |
       "ought" "to" "have" "been" [<Vpastp> | <Ving>] |
       ("do" |"does" |"did") [<Vinf>] |
       ("am" |"are" |"is" |"was" |"were") [<Vpastp> | <Ving>] |
       ("am" |"are" |"is" |"was" |"were") "being" [<Vpastp>] |
       ("am" |"are" |"is" |"was" |"were") "going" "to" [<Vinf>]

Verb Phrase Examples:
("had" |"have" |"has") <Vpastp>
has gone, had finished

("had" |"have" |"has") "been" [<Vpastp> | <Ving>]
had been studying, has been gone

<auxV> "have" <Vpastp>
would have gone, might have studied

<auxV> "have" "been" [<Vpastp> | <Ving>]
will have been gone, should have been studying

<auxV> "be" [<Vpastp> | <Ving>]
will be gone, must be studied

<auxV> <Vinf>
will go, must study

"ought" "to" <Vinf>
ought to study

"ought" "to" "have" "been" [<Vpastp> | <Ving>]
ought to have been studying

("do" |"does" |"did") [<Vinf>]
do, did study, does swim

("am" |"are" |"is" |"was" |"were") [<Vpastp> | <Ving>]
are, is gone, were swimming

("am" |"are" |"is" |"was" |"were") "being" [<Vpastp>]
are being, was being punished

("am" |"are" |"is" |"was" |"were") "going" "to" [<Vinf>]
am going to travel, is going to study

Verb Tense

Verb tenses are inflectional forms of verbs or verb phrases that are used to express time distinctions. The following table defines the structure of some common verb tenses. The grammatical term "perfect" expresses an action or state completed at the time of speaking or at a time spoken of. "Continuous" indicates an on-going action.

Simple Present	Simple Past	Simple Future
<V1s>|<V2s>|<V3s>| <V1p>|<V2p>|<V3p>   John studies everyday. They study everyday.	<Vpast>   Mary studied yesterday.	"will" <Vinf>   ("am"|"are"|"is") "going" "to" <Vinf>   John will help you tomorrow. Mary is going to help you tomorrow.
Present Continuous	Past Continuous	Future Continuous
("am"|"are"|"is") <Ving>   John is studying now.	("was"|"were") <Ving>   John was studying yesterday.	"will" "be" <Ving>   ("am"|"are"|"is") "going" "to" "be" <Vinf>   Mary will be studying tomorrow. Mary is going to be studying tomorrow.
Present Perfect	Past Perfect (Pluperfect)	Future Perfect
("have"|"has") <Vpastp>   John has studied for three years.	"had" <Vpastp>   She had studied English before coming here.	"will" "have" <Vpastp>   By December, she will have studied for three years.
Present Perfect Continuous	Past Perfect Continuous	Future Perfect Continuous
("have"|"has") "been" <Ving>   She has been studying for three years.	"had" "been" <Ving>   Mary had been studying for three days when she got sick.	"will" "have" "been" <Ving>   By midnight, John will have been studying for over three hours.

Adverbial Particles

Some verbs acquire a different meaning when they are followed by "adverbial particles". The most common adverbial particles are:
about, across, along, around, behind, by, down, forward, in, off, on, out, over, through, up

Adverbial particles are prepositions that are considered part of the verb. The expression "get up", for instance, means to "rise". It is not a request to "obtain" anything. Many of the verbs associated with adverbial particles are separable. One or more words may appear between the verb and the particle.

Examples:
"I will wake up early tomorrow."
"I will wake him up early tomorrow."

In traditional grammars, verbs that may be separated from their particles by a noun or pronoun are called "phrasal verbs". The word "up" in the example above is considered an adverb, rather than a preposition. Verbs for which the particle must remain by the verb are called "prepositional verbs". The adverbial particles of prepositional verbs may be interpreted either as adverbs or as prepositions which start a prepositional phrase.

Complements of Verbs

The predicate consists of a verb or verb phrase and its complements, if any. A verb that requires no complements is called intransitive. A verb that requires one or two complements is called transitive. A verb may belong to both categories. We may generate the complete sentence "I walk." with no complements. We may also generate "I walk home.", where "home" is a complement of the verb. Further, "I walk my dog home." has two complements: "my dog" and "home". In traditional grammars, these complements are called the "indirect object" (my dog) and the "direct object" (home). In this formal description they are called the <indirect object> and <object>. The complement of a verb or verb phrase is described as being optional and consisting not only of objects, but of adjectives, prepositional phrases, etc. This is the formal description:

<complement> =
       [[<indirect object>] <object>] |
       [<adverb>* <adjective>] |
       [<prep phr>*] |
       ["to" <Vinf> [<object>]] |
       [<Ving>]

The <adverb>* <adjective> option is for linking verbs or linking verb phrases.
The <prep phr>* option is for intransitive or linking verbs. The format of an <indirect object> is the same as an <object>:

<indirect object> = <object> =
       <simple object> | <compound object>

Notice that objective personal pronouns are used in objects.

<simple object> = <noun phrase> |
       <objective personal pronoun>

<compound object> =
       <simple object> ("and" | "or") <simple object>

Examples of Sentences with Complements:
[<indirect object>] <object>
I spent the money.
John gave me the little book.

<adverb>* <adjective>
Mary became very angry.

<prep phr>*
John slept until 10:00 AM on Thursday.

"to" <Vinf> [<object>]
John went to pay the rent.
I want to drink water.

<Ving>
John went shopping.