基于ANSYS经典界面的光盘轴的转子动力学分析（谐响应分析）

【问题描述】

一个悬臂光盘轴系统如下图所示。该系统由三个零件组成：一根轴，一片光盘以及一个刚性夹子（该夹子在图中没有绘制）。轴的左端固定，而由端通过刚性夹子与光盘的内圈固定。此轴以0.75*50hz的转速旋转。现在此轴的固定端处施加一个简谐力，该力沿着-Y方向，频率从0-500HZ.想要考察该光盘的中心点的幅频关系曲线。

X
相关的数据包括：
（1）光盘的几何尺寸
厚度: 1.0 mm
内半径: 0.1016 m
外半径: 0.2032 m
（2）光盘轴的几何尺寸
长度: 0.4064 m
半径: 0.0132 m
（3）刚性夹的惯性属性
质量： 6.8748 kg
惯性矩(XX,YY)： 0.0282 kg.m²
惯性矩(ZZ) ： 0.0355 kg.m²
(4)轴与光盘的材料
弹性模量(E) ： 2.04e+11 N/m2
泊松比 (υ)： 0.28
密度 ： 8030 kg/m³

《注》该算例来自于ANSYS APDL转子动力学部分的帮助实例。

---

【范例

说明】 给出本例子的目的，是想说明：
（1）如何使用模态叠加法进行谐响应分析。
（2）如何在对基础施加加速度激励。
（3）如何建模刚性联接件。

---

【问题分析】

1.这是一个谐响应分析。准备使用模态叠加法来分析此问题，因此需要经过三个步骤：（1）模态分析（2）谐响应分析（3）模态展开。在模态分析阶段需要考虑科里奥利效果。
2.对于轴使用BEAM188建模，对于光盘用SHELL181建模，对于刚性夹子的建模注意两点。（1）用一个MASS21单元来表示其惯性（2）用刚性区域命令在转轴与光盘的内圈之间建立一个刚性区域。
3.边界条件：轴的固定端全约束。
4.为了表达基础激励，在模态分析阶段计算Y方向的加速度，而在谐响应分析阶段使用该加速度矢量。
5.本文将用命令流的方式进行讲解。

---

---

【求解过程】

一 建模
1.定义变量
在命令窗口中输入下列命令
pi = acos(-1)
xb = 0.1016
xa = 0.2032
zh = 1.0e-3
rs = 0.0191
ls = 0.4064
d1 = 0.0132
spin = 50*2*pi*0.75
fexcit = 500
这些命令的目的是定义一些变量，以便下面使用。要知道其具体含义，在下面出现这些参数时回头查找就可以了解。
2.定义材料模型
继续输入
/prep7
mp,ex,,2.04e+11
mp,nuxy,,.28
mp,dens,,8030.
其含义是：
第1行：进入前处理器
第2-4行：设置材料的弹性模量，泊松比和密度。
3.创建转轴的有限元模型
（1）定义单元及截面
继续输入
et,1,188
sectype,1,beam,csolid
secd,rs,30
这三行命令指明了
第1行：转轴的单元类型是BEAM188;
第2行：转轴截面是实心圆
第3行：该实心圆的半径是rs,而rs是一个变量，从前面的变量定义可以知道:rs= 0.0191
（2）创建几何模型
继续输入
k,1,,,-ls-d1
k,2,,,-d1
l,1,2
这三行命令指明了
第1行：创建转轴的一个端点;
第2行：创建转轴的另一个端点;
第3行：将这两个端点连成直线。
然后执行
/PNUM,KP,1
/PNUM,LINE,1
/PNUM,NODE,1
/VIEW,1,,1
/ANG,1
/REP,FAST
LPLOT
前三行说明要打开关键点，直线以及节点的编号显示
后四行说明要查看俯视图，并更新主窗口，并查看直线。
执行完毕后，主窗口显示如下：

（3）划分有限元模型
继续输入
lesize,1,,,5
type,1
secn,1 lmesh,all
这4行命令指明了
第1行：设置将该直线划分为5个单元
第2-3行：指明下面用到的单元类型及截面属性
第4行：划分网格。
执行完毕后，主窗口显示如下：

4.创建光盘的有限元模型
（1）定义单元及截面
继续输入
et,2,181
sectype,2,shell
secd,zh
这三行命令指明了
第1行：光盘的单元类型是SHELL181
第2-3行：指明光盘的厚度是zh=1.0e-3
（2）创建几何模型
继续输入
cyl4,,,xb,0,xa,360
/VIEW,1,1,1,1
/ANG,1
/REP,FAST
其含义是，定义一个圆环，并用轴测图的方式查看
执行完毕后，主窗口显示如下：

（3）划分有限元模型
继续输入
esize,0.01
type,2
secn,2
amesh,all
这4行命令指明了
第1行：设置划分该光盘的单元尺寸是0.01
第2-3行：指明下面用shell181划分网格，厚度是1.0e-3
第4行：划分网格。
再输入
/PNUM,NODE,0
/REP,FAST
以关闭节点显示
执行完毕后，主窗口显示如下：

5.创建刚性夹的有限元模型
（1）定义建模刚性夹的质量单元
继续输入
et,3,21
r,3,6.8748,6.8748,6.8748,0.0282,0.0282,0.0355
其中，
第1行：创建单元MASS21
第2行：定义MASS21的惯性属性
（2）在原点处创建一个质量单元以建模刚性夹
继续输入
n,
ncent = node(0,0,0)
type,3
real,3 e,ncent
其中，
第1行：在坐标原点处创建一个节点，该节点的编号由ANSYS自己确定。
第2行：定义1个变量ncent ，由该变量存储原点处那个节点的编号。
第3-4行：指明下面划分网格的单元是MASS21，并使用前面给出的惯性量。
第5行：在坐标原点的节点上创建质量单元，该点质量代表了刚性夹的惯性属性。
执行完毕后，主窗口显示如下：

可见，原点处创建了一个节点。
（3）在转轴和光盘的内圈之间创建刚性区域
继续输入
cerig,ncent,node(0,0,-d1),all
其含义是：在原点处的节点和靠近光盘的转轴端点之间建立刚性区域
执行完毕后，主窗口显示如下：

继续输入
csys,1
nsel,,loc,x,xb
nsel,a,node,,ncent
cerig,ncent,all,all
allsel
csys,0
其中，
第1行：设定下面要使用圆柱坐标系
第2行：选择光盘内圈的所有节点
第3行：继续选择原点处的那个节点
第4行：在上述节点之间建立刚性区域
第5行：选择所有对象，以便下面的操作
第6行：把坐标系切换为直角坐标系
执行完毕后，主窗口显示如下：

6.约束转轴的固定端
继续输入
nsel,,node,,node(0,0,-ls-d1)
d,all,all,0.0
allsel
fini
其中，
第1行:找到转轴的固定端
第2行:将该固定端的所有自由度都约束住
第3行:选择所有对象，以便下面的操作
第4行:退出前处理器
执行完毕后，主窗口显示如下：

二 分析
1. 模态分析
（1）设置分析类型及分析选项
继续输入
/solu
antype,modal
modopt,qrdamp,30
mxpand,30
betad,1.e-5
其中，
第1行：进入求解器
第2行：设置新分析类型为模态分析
第3行：设置采用QRDAMP来提取前30阶模态
第4行：展开这30阶模态
第5行：设置betad阻尼值的大小，意味着要做有阻尼的模态分析。
（2）打开科里奥利效应
继续输入
coriolis,on,,,on
omega,,,spin
其中，
第1行：打开科里奥利效应，使用固定坐标系计算
第2行：设置轴的旋转速度
（3）施加基础的加速度激励
继续输入
acel,,-1
说明计算加速度基础激励
（4）求解
继续输入
solve
fini
说明要开始模态分析，分析完毕后退出求解器。
2. 谐响应分析
（1）设置分析类型及分析选项
继续输入
/solu
antype,harmonic
hropt,msup,30
其中，
第1行：再次进入到求解器
第2行：设置要做谐响应分析
第3行：设置要使用模态叠加法，前面提取的30阶模态都要包含进来。
继续输入
harfrq,,fexcit
nsubst,500 kbc,0
其中，
第1行：指定谐响应分析的频率范围,从0-fexcit（= 500）
第2行：指定在此范围内设置500个载荷子步
第3行：指定激励是阶跃激励
继续输入
outres,all,none
outres,nsol,all
其中，
第1行：不要输出任何结果
第2行：但是要输出节点解的结果
由于计算量很大，如果不这样限制输出结果，可能会内存不够。
（2）使用基础的加速度激励
继续输入
acel,0,0,0
lvscale,1.0
其中，
第1行：无加速度激励
第2行：请使用在模态分析中得到的加速度激励
（3）求解
继续输入
solve
fini
其含义是：开始做谐响应分析，分析完后退出求解器。
3. 模态展开
继续输入
/solu
expass,on
numexp,all
solve
fini
其含义是：
再次进入到求解器，
进入到模态展开阶段，
展开所有模态，
然后开始计算，
计算完后退出求解器。
三 后处理
（1）获取节点的位移变量
继续输入
/post26
nsol,2,node(0,0,0),U,X,uxTip
nsol,3,node(0,0,0),U,Y,uyTip
nsol,4,node(0,xa,0),U,Z,uzDisk
其含义是：
第1行：进入时间历程后处理器
第2行：把光盘圆心处节点的X位移提取出来放入变量2.
第3行：把光盘圆心处节点的y位移提取出来放入变量3.
第4行：把光盘边沿上某一个节点的位移提取出来放入变量4.
继续输入
/gropt,logy,on
/axlab,x,FREQUENCIES
/axlab,y,DISPLACEMENTS (m)
plvar,2,3,4
前3行用于对下面要画的图进行蛇者
第1行： 指定图形的Y轴使用对数坐标
第2行：图形的X轴用 FREQUENCIES作为标签
第3行：图形的Y轴用 DISPLACEMENTS (m)作为标签
第4行：绘制上述3个幅频曲线图。
执行完毕后，主窗口显示如下：