本篇是对昨天文章 Mark体系梳理(确认与违反)的修订版,增加了部分内容(斜线加粗部分)
前文 Mark体系梳理(网球行为TBA)说到Mark用TBA来识别突破后是否自然反应(NR),换句话就是继续持仓还是开始减仓?
有没有更细致可量化的标准?有!
持仓标准Confirmation(确认)如下:
1、跟进买入
机构蜂拥而至在图形上的表现就是连续的放量拉升
要注意区分机构买入还是散户买入,因为散户买入通常没有持续性
2、上涨天数>下跌天数
涨多跌少是老生常谈,不再赘述
3、好收盘天数>坏收盘天数
收盘价越靠近最高价越好,最高价收盘说明机构当天还没买够
A股特殊的短线打板玩法,其实也是在博弈隔日会继续购买
4、Tennis Ball Action 网球行为
上述条件多数时候都是伴随TBA一起发生(参考前文)
5、最强标准MVP
15天内有12天上涨、涨幅20%以上、放量25%以上(原书《股魔2》P13)
减仓标准Violation(违反)如下:(原书《股魔2》P18)
1、低量突破高量跌回
2、下跌天数>上涨天数
3、坏收盘天数>好收盘天数
4、突破后快速跌破20线或50线(放量)
5、连续3-4个低点无支撑
需要提醒小伙伴的是:偶尔出现个别Violation不要紧,但是当Violation累积较多时要开始考虑减仓
有小伙伴心想:这么多条记不住怎么办?贴心的冬哥已经给小伙伴准备好公式,效果如图:
红色代表Confirmation、绿色代表Violation,红绿数量变化可以作为加减仓参考(免责声明:指标仅供参考,不构成买卖建议)
公式代码如下:
DAYS:=15; {天数范围, 直接定义或公式参数}
UPC:=COUNT(C>REF(C,1),DAYS);
DNC:=COUNT(C<REF(C,1),DAYS);
UPDN:=IF(UPC>DNC,1,-1); {上涨天数>下跌天数取1, 反之取-1}
GCC:=COUNT((C-L)/(H-L)>0.5,DAYS);
BCC:=COUNT((C-L)/(H-L)<0.5,DAYS);
GCBC:=IF(GCC>BCC,1,-1); {好收盘天数>坏收盘天数取1, 反之取-1}
HV:=V>REF(V,1) AND V>MA(V,50);
HVUD:=IF(C>REF(C,1) AND HV,1,IF(C<REF(C,1) AND HV,-1,0)); {放量涨取1, 放量跌取-1}
LL3:=IF(EVERY(L<REF(L,1),3),-1,0); {3新低取-1}
BL10:=IF(C<MA(C,10),-1,0); {<10线取-1}
BL20:=IF(C<MA(C,20),-1,0); {<20线取-1}
BL50:=IF(C<MA(C,50),-1,0); {<50线取-1}
7.5,COLORBLACK;
DRAWTEXT(ISLASTBAR,7,' 涨跌'),COLORLIGRAY;
DRAWTEXT(ISLASTBAR,6,' 收盘'),COLORLIGRAY;
DRAWTEXT(ISLASTBAR,5,' 放量'),COLORLIGRAY;
DRAWTEXT(ISLASTBAR,4,' 3新低'),COLORLIGRAY;
DRAWTEXT(ISLASTBAR,3,' <10线'),COLORLIGRAY;
DRAWTEXT(ISLASTBAR,2,' <20线'),COLORLIGRAY;
DRAWTEXT(ISLASTBAR,1,' <50线'),COLORLIGRAY;
0.5,COLORBLACK;
DRAWTEXT(UPDN>0,7,'●'),COLORRED;
DRAWTEXT(GCBC>0,6,'●'),COLORRED;
DRAWTEXT(HVUD>0,5,'●'),COLORRED;
DRAWTEXT(UPDN<0,7,'●'),COLORGREEN;
DRAWTEXT(GCBC<0,6,'●'),COLORGREEN;
DRAWTEXT(HVUD<0,5,'●'),COLORGREEN;
DRAWTEXT(LL3<0,4,'●'),COLORGREEN;
DRAWTEXT(BL10<0,3,'●'),COLORGREEN;
DRAWTEXT(BL20<0,2,'●'),COLORGREEN;
DRAWTEXT(BL50<0,1,'●'),COLORGREEN;
感谢热心的小伙伴提醒公式问题,正好借着机会,给群里小伙伴发了几个红包(本篇主要是修订、不开赞赏)
联系客服