成交额附图公式（通达信）

　　从2011-06-20以来的最近这段时间，上证指数大盘出现了几次“百日地量”，但是有两次出现在下跌中继途中。

　　如果我们把“成交量”换成“成交金额”，则可以看出，成交额的“百日地量”更准确地出现在大盘的相对低点，为我们研判大盘的相对底部，提供更为实用的参考价值。

　　下面根据笔者在“股海明灯论坛”的个人空间日志发表的公式：通达信软件(量柱)直观显示：倍量柱+三天价涨量缩=真黄金柱公式（带低量柱）
http://u.178448.com/space.php?uid=30578do=blogid=1201

将“成交量”换成“成交金额”，编成“成交额附图公式”（适用于通达信行情软件），供大家参考。这个也与《狙击涨停板》作者张华老师的理念相符。

　　具体图形请参阅：从成交额看今日大盘是百日地量（http://blog.sina.com.cn/s/blog_7f809c880100up3h.html）

 

{成交额附图公式VOL_日志改AM  用成交额代替成交量}
{看图说明：黄色为倍量柱，白色为并肩平量柱，紫色为缩倍柱，
绿色为10天低量柱，蓝色为50天低量柱，灰色为百日低量柱，
高量柱容易看无标记，！为长阴短柱, 内有红实线为假阴柱。
红色箭头(的前三天)为黄金柱。次黄金柱难判,不标记}

绿低量:=10;{178448-WEN98编制}
蓝低量:=50;
灰低量:=100;
{--------VOL.量能饱和--------}
N1:=21;
AM:= AMOUNT/100000000,NODRAW;{成交额亿}
SAT:=(AM/C)/(HHV(AM,20)/HHV(C,20));
量能饱和度:IF(SAT>1,1,SAT)*100,COLOR00AAFF,NODRAW;
中点:=REFDATE(HHV(AM,180)*0.5,DATE);
STICKLINE(CURRBARSCOUNT=N1,中点*1.9,中点*1.5,100,1),COLOR00AAFF;
STICKLINE(CURRBARSCOUNT=N1,中点*1.88,中点*1.52,量能饱和度,0),COLOR0077FF;
DRAWTEXT(CURRBARSCOUNT=N1+3,中点*1.8,'饱和度'),COLORYELLOW;
{=====================================================}
H_L:=0.1*CONST(HHV(AM,240));
{MAV10:MA(V,10),COLORYELLOW;}
异动135:MA(AM,135),COLORMAGENTA;
洗盘40:MA(AM,40),COLORBLUE;
启动5:MA(AM,5),COLORWHITE;

VVOL:=IF(CURRBARSCOUNT=1 ANDPERIOD=5,AM*240/FROMOPEN,DRAWNULL);{模拟量}
STICKLINE(CURRBARSCOUNT=1 ANDPERIOD=5,VVOL,0,1,-1),COLOR00C0C0;
量:V,COLORGREEN,NODRAW;
成交额亿:AM,VOLSTICK,COLORLIGRAY;
换手: VOL*10000/FINANCE(7),NODRAW,COLORGREEN;{DYNAINFO(37)*100}
全换手周期: SUMBARS(V,CAPITAL),NODRAW,COLORLIGREEN;{求完全换手到现在的周期数}
量比: V/REF(MA(V,5),1),COLORBROWN,NODRAW;
几倍: AM/REF(AM,1),COLORYELLOW,NODRAW;
倍数:=1.9;{178448-WEN98编制}
倍量: AM>=REF(AM,1)*倍数 AND(IF(C<O,C>REF(C,1),1)),COLORYELLOW,NODRAW;
倍缩: REF(AM,1)>=AM*倍数,COLORMAGENTA,NODRAW;
平量: RANGE(AM/REF(AM,1),0.97,1.03) ANDBARSCOUNT(V)>=2,COLORWHITE,NODRAW;
低量10: AM=LLV(AM,绿低量) ANDBARSCOUNT(AM)>=绿低量,COLORGREEN,NODRAW;
低量50: AM=LLV(AM,蓝低量) ANDBARSCOUNT(AM)>=蓝低量,COLORBLUE,NODRAW;
地量:   AM=LLV(AM,灰低量) ANDBARSCOUNT(AM)>=灰低量,COLORGRAY,NODRAW;

V1:=AM*0.9;{图标位置}
V2:=AM*0.8;
STICKLINE(倍量, 0,V1,1,0),COLORYELLOW;
STICKLINE(平量,0,V1,1,0),COLORWHITE;
STICKLINE(低量10,0,V2,1,0),COLORLIGREEN;
STICKLINE(低量50,0,V2,1,0),COLORBLUE;
STICKLINE(地量,0,V2,1,0),COLORGRAY;
STICKLINE(倍缩,0,AM*0.45,1,0),COLORMAGENTA;
STICKLINE(C<O ANDC>REF(C,1),0,AM,0,0),COLORRED;{假阴柱}

真阳或假阴:=C>O ORC>REF(C,1);
收阳:= REF(真阳或假阴,3);
倍量1:=REF(倍量,3);
高量:=REF(AM,3)>=HHV(AM,7);
三日不破:= LLV(C,3)>=REF(L,3);
价升:=COUNT(C>=REF(C,1),3)=3;{收盘价逐升}
量缩:=COUNT(AM<=REF(AM,1),3)=3;
连阳:= COUNT(真阳或假阴,3)=3;
倍量将军柱:= 倍量1 AND 三日不破 AND 收阳;
高量将军柱:= 高量  AND 三日不破 AND 收阳;
将军柱:= 倍量将军柱 OR 高量将军柱;
黄金柱:= 将军柱 AND 价升 AND 量缩 AND 连阳 ;
STICKLINE(黄金柱,0.3*AM,0.7*AM,1,0),COLORRED; {红柱}
DRAWICON(黄金柱,AM*1.5,1);

V100:= AM<=LLV(AM,100)*1.2AND V>0 AND BARSCOUNT(AM)>=100;
百日地量群:=COUNT(V100,5)>=3;
DRAWTEXT(FILTER(百日地量群,4),AM+3*H_L,'地量群'),COLORGRAY;

长阴短柱:=C/REF(C,1)<=0.96 ANDAM<HHV(AM,30)/1.9;
DRAWTEXT(长阴短柱 ,AM+1.6*H_L,'！'),COLORLICYAN;