多彩Ｋ线主图公式(通达信)

今天BLOG的流量突破40000，为了感谢大家的支持，这里给出一个“多彩Ｋ线主图公式”，希望能给大家一点帮助！功能是用不同的色彩，直观显示大阳\大阴\涨停\跌停\假阴等Ｋ线，一看就明白。可以单独使用，也可加到你主图系统的后边，或适当位置。（本贴下方有改进公式）

 

{多彩Ｋ线主图公式,显示大阳\大阴\涨停\跌停\假阴,适用于通达信}
{可加到你主图的均线系统的后边}
{6\20均线}
MA6: MA(C,6 ),COLORGREEN;{王子操盘线}
MA6_: IF(MA6>=REF(MA6,1),MA6,DRAWNULL),COLORMAGENTA;
MA20: MA(C,20),COLORLICYAN;{万能线}
MA20_: IF(MA20>=REF(MA20,1),MA20,DRAWNULL),COLORLIRED;

{重绘K线 显示大阳\大阴\涨停\跌停\假阴,适用于通达信}
DRAWKLINE(H,O,L,C);{重绘K线}
{重绘K线 显示大阳\大阴\涨停\跌停\假阴,适用于通达信}
RC1:=REF(C,1);
涨停率10:=10-1/RC1;{178448-WEN98编写}
涨停率5:=5-1/RC1;
比前涨率:=(C-RC1)*100/RC1;
比前跌率:=(RC1-C)*100/RC1;
ST:=NAMELIKE('ST') OR NAMELIKE('*ST');
涨停:= IF(ST, (比前涨率>=涨停率5), (比前涨率>=涨停率10));
本日涨率:=(C-O)*100/O;
本日跌率:=(O-C)*100/O;
STICKLINE((H-RC1)*100/RC1>=涨停率10,H,MAX(C,O),0,0),COLORMAGENTA;{涨停后回落}
STICKLINE((RC1-L)*100/RC1>=涨停率10,L,MIN(C,O),0,0),COLORBLUE;{跌停后回升}
STICKLINE(涨停,O,C,1,0),COLORMAGENTA;{COLOR00AAFF;}
跌停:= IF(NAMELIKE('ST'), (比前跌率>=涨停率5), (比前跌率>=涨停率10));
STICKLINE(跌停,O,C,1,0),COLORBLUE;
大阳线:=C>O AND (比前涨率>=涨停率5 OR 本日涨率>=涨停率5)
        AND 比前涨率<涨停率10 AND 涨停=0;
STICKLINE(大阳线,O,C,1,0),COLOR0000BB;
大阴线:=C<O AND (比前跌率>=涨停率5 OR 本日跌率>=涨停率5)
        AND 比前跌率<涨停率10 AND 跌停=0;
STICKLINE(大阴线,O,C,1,0),COLORLIGREEN;
假阴:=C<O AND C>REF(C,1);
STICKLINE(假阴,O,C,0,0),COLORRED;{假阴柱};

 

这是效果图：

>===========================================================================================<

2011-09-29改进后(增加跳空显示):

{多彩Ｋ线主图公式,显示大阳\大阴\涨停\跌停\假阴\跳空,适用于通达信}
{可加到你主图的均线系统的后边

{MA120: MA(C,120),COLORGRAY;
MA60: MA(C,60),COLORBLUE;
MA30: MA(C,30),COLORLICYAN;
MA30_: IF(MA30>=REF(MA30,1),MA30,DRAWNULL),COLORLIRED;

MA10: MA(C,10),COLORYELLOW;
MA5: MA(C,5),COLORGREEN;
MA5_: IF(MA5>=REF(MA5,1),MA5,DRAWNULL),COLORMAGENTA;}
{如果只要裸K线,则上面均线部分可以去掉;如果要显示均线,可去掉上段大括号}
{========================================================}
{跳空}
STICKLINE(REF(L,1)>H,H,REF(L,1),5,0),COLORGRAY;
STICKLINE(REF(H,1)<L,L,REF(H,1),5,0),COLORGRAY;
{重绘K线 显示大阳\大阴\涨停\跌停\假阴,适用于通达信}
DRAWKLINE(H,O,L,C);{重绘K线}
{重绘K线 显示大阳\大阴\涨停\跌停\假阴,适用于通达信}
RC1:=REF(C,1);
涨停率10:=10-1/RC1;{178448-WEN98编写}
涨停率5:=5-1/RC1;
比前涨率:=(C-RC1+0.004)*100/RC1;
比前跌率:=(RC1-C-0.004)*100/RC1;
ST:=NAMELIKE('ST') OR NAMELIKE('*ST');
涨停:= IF(ST, (比前涨率>=涨停率5), (比前涨率>=涨停率10));
跌停:= IF(ST, (比前跌率>=涨停率5), (比前跌率>=涨停率10));
盘中涨停:=(H-RC1+0.004)*100/RC1>=IF(ST, 涨停率5,涨停率10);
盘中跌停:=(RC1-L-0.004)*100/RC1>=IF(ST, 涨停率5,涨停率10);
STICKLINE(盘中涨停,H,MAX(C,O),0,0),COLORMAGENTA;{涨停后回落}
STICKLINE(盘中跌停,L,MIN(C,O),0,0),COLORLICYAN;{跌停后回升}
STICKLINE(涨停,O,C,1,0),COLORMAGENTA;
STICKLINE(跌停,O,C,1,0),COLORLICYAN;
本日涨率:=(C-O+0.004)*100/O;
本日跌率:=(O-C-0.004)*100/O;
大阳线:=C>O AND (比前涨率>=涨停率5 OR 本日涨率>=涨停率5)
        AND 比前涨率<涨停率10 AND 涨停=0;
STICKLINE(大阳线,O,C,1,0),COLOR0000BB;
大阴线:=C<O AND (比前跌率>=涨停率5 OR 本日跌率>=涨停率5)
        AND 比前跌率<涨停率10 AND 跌停=0;
STICKLINE(大阴线,O,C,1,0),COLORLIGREEN;
假阴:=C<O AND C>REF(C,1);
STICKLINE(假阴,O,C,0,0),COLORRED;{假阴柱};

 

下面是效果图与图例：（实心红－大阳，红到发紫-涨停，实心绿－大阴，绿到发蓝－跌停）